nightshade 0.8.2

A cross-platform data-oriented game engine.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

struct HudUniforms {
    projection: mat4x4<f32>,
    color: vec4<f32>,
    outline_color: vec4<f32>,
    outline_width: f32,
    depth: f32,
    _padding: vec2<f32>,
}

@group(0) @binding(0) var<uniform> uniforms: HudUniforms;
@group(1) @binding(0) var font_texture: texture_2d<f32>;
@group(1) @binding(1) var font_sampler: sampler;
@group(1) @binding(2) var<storage, read> character_colors: array<vec4<f32>>;

struct VertexInput {
    @location(0) position: vec3<f32>,
    @location(1) tex_coords: vec2<f32>,
    @location(2) character_index: u32,
}

struct VertexOutput {
    @builtin(position) position: vec4<f32>,
    @location(0) tex_coords: vec2<f32>,
    @location(1) @interpolate(flat) character_index: u32,
}

@vertex
fn vs_main(vertex: VertexInput) -> VertexOutput {
    var output: VertexOutput;

    output.position = uniforms.projection * vec4<f32>(vertex.position.xy, vertex.position.z, 1.0);
    output.position.z = uniforms.depth;
    output.tex_coords = vertex.tex_coords;
    output.character_index = vertex.character_index;
    return output;
}

@fragment
fn fs_main(input: VertexOutput) -> @location(0) vec4<f32> {
    let distance = textureSample(font_texture, font_sampler, input.tex_coords).r;

    let grad = vec2<f32>(dpdx(distance), dpdy(distance));
    let smoothing = length(grad) * 0.5;

    let alpha_base = smoothstep(0.5 - smoothing, 0.5 + smoothing, distance);

    let char_color = character_colors[input.character_index];
    let use_override = char_color.a > 0.0;
    let base_color = select(uniforms.color, char_color, use_override);

    if uniforms.outline_width > 0.0 {
        let outline_threshold = 0.5 - uniforms.outline_width;
        let alpha_outline = smoothstep(outline_threshold - smoothing, outline_threshold + smoothing, distance);

        let final_color = mix(uniforms.outline_color, base_color, alpha_base / alpha_outline);
        return vec4<f32>(final_color.rgb, final_color.a * alpha_outline);
    } else {
        return vec4<f32>(base_color.rgb, base_color.a * alpha_base);
    }
}