ramp 0.7.0

A high-performance multiple-precision arithmetic library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194

    .text
    .file "addsub_n.S"

#define wp %rdi
#define xp %rsi
#define yp %rdx
#define n %rcx

    .section .text.ramp_add_n,"ax",@progbits
    .globl ramp_add_n
    .align 16, 0x90
    .type ramp_add_n,@function
ramp_add_n:
    .cfi_startproc

#define L(lbl) .LADD_ ## lbl

    mov %ecx, %eax
    shr $2, n
    and $3, %eax
    jrcxz L(lt4)

    mov (xp), %r8
    mov 8(xp), %r9
    dec n
    jmp L(mid)

L(lt4):
    dec %eax
    mov (xp), %r8
    jnz L(2)
    adc (yp), %r8
    mov %r8, (wp)
    adc %eax, %eax
    ret

L(2):
    dec %eax
    mov 8(xp), %r9
    jnz L(3)
    adc (yp), %r8
    adc 8(yp), %r9
    mov %r8, (wp)
    mov %r9, 8(wp)
    adc %eax, %eax
    ret

L(3):
    mov 16(xp), %r10
    adc (yp), %r8
    adc 8(yp), %r9
    adc 16(yp), %r10
    mov %r8, (wp)
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    setc %al
    ret

    .align 16
L(top):
    adc (yp), %r8
    adc 8(yp), %r9
    adc 16(yp), %r10
    adc 24(yp), %r11
    mov %r8, (wp)
    lea 32(xp), xp
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    dec n
    mov %r11, 24(wp)
    lea 32(yp), yp
    mov (xp), %r8
    mov 8(xp), %r9
    lea 32(wp), %rdi
L(mid):
    mov 16(xp), %r10
    mov 24(xp), %r11
    jnz L(top)

L(end):
    lea 32(xp), xp
    adc (yp), %r8
    adc 8(yp), %r9
    adc 16(yp), %r10
    adc 24(yp), %r11
    lea 32(yp), yp
    mov %r8, (wp)
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    mov %r11, 24(wp)
    lea 32(wp), wp

    inc %eax
    dec %eax
    jnz L(lt4)
    adc %eax, %eax
    ret
L(tmp):
    .size ramp_add_n, L(tmp) - ramp_add_n
    .cfi_endproc

    .section .text.ramp_sub_n,"ax",@progbits
    .globl ramp_sub_n
    .align 16, 0x90
    .type ramp_sub_n,@function
ramp_sub_n:
    .cfi_startproc

#undef L
#define L(lbl) .LSUB_ ## lbl

    mov %ecx, %eax
    shr $2, n
    and $3, %eax
    jrcxz L(lt4)

    mov (xp), %r8
    mov 8(xp), %r9
    dec n
    jmp L(mid)

L(lt4):
    dec %eax
    mov (xp), %r8
    jnz L(2)
    sbb (yp), %r8
    mov %r8, (wp)
    adc %eax, %eax
    ret

L(2):
    dec %eax
    mov 8(xp), %r9
    jnz L(3)
    sbb (yp), %r8
    sbb 8(yp), %r9
    mov %r8, (wp)
    mov %r9, 8(wp)
    adc %eax, %eax
    ret

L(3):
    mov 16(xp), %r10
    sbb (yp), %r8
    sbb 8(yp), %r9
    sbb 16(yp), %r10
    mov %r8, (wp)
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    setc %al
    ret

    .align 16
L(top):
    sbb (yp), %r8
    sbb 8(yp), %r9
    sbb 16(yp), %r10
    sbb 24(yp), %r11
    mov %r8, (wp)
    lea 32(xp), xp
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    dec n
    mov %r11, 24(wp)
    lea 32(yp), yp
    mov (xp), %r8
    mov 8(xp), %r9
    lea 32(wp), %rdi
L(mid):
    mov 16(xp), %r10
    mov 24(xp), %r11
    jnz L(top)

L(end):
    lea 32(xp), xp
    sbb (yp), %r8
    sbb 8(yp), %r9
    sbb 16(yp), %r10
    sbb 24(yp), %r11
    lea 32(yp), yp
    mov %r8, (wp)
    mov %r9, 8(wp)
    mov %r10, 16(wp)
    mov %r11, 24(wp)
    lea 32(wp), wp

    inc %eax
    dec %eax
    jnz L(lt4)
    adc %eax, %eax
    ret
L(tmp):
    .size ramp_sub_n, L(tmp) - ramp_sub_n
    .cfi_endproc