ramp 0.7.0

A high-performance multiple-precision arithmetic library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93

    .text
    .file "addmul_1.S"

#define wp %rdi
#define xp %rsi
#define n_param %edx
#define n %r11d
#define v %rcx

    .section .text.ramp_addmul_1,"ax",@progbits
    .globl ramp_addmul_1
    .align 16, 0x90
    .type ramp_addmul_1,@function
ramp_addmul_1:
    .cfi_startproc

#define L(lbl) .LADDMUL_ ## lbl

    mov n_param, n # Move n away from %rdx

    mov (xp), %rax
    mul v
    add %rax, (wp)
    adc $0, %rdx
    mov %rdx, %r8

    dec n
    jz L(ret)
    add $8, wp
    add $8, xp
    .align 16
L(top):
    mov (xp), %rax
    mul v
    add %r8, %rax
    adc $0, %rdx
    mov %rdx, %r8
    add %rax, (wp)
    adc $0, %r8

    add $8, wp
    add $8, xp
    dec n
    jnz L(top)
L(ret):
    mov %r8, %rax
    ret
L(tmp):
    .size ramp_addmul_1, L(tmp) - ramp_addmul_1
    .cfi_endproc

    .section .text.ramp_submul_1,"ax",@progbits
    .globl ramp_submul_1
    .align 16, 0x90
    .type ramp_submul_1,@function
ramp_submul_1:
    .cfi_startproc

#undef  L
#define L(lbl) .LSUBMUL_ ## lbl

    mov n_param, n # Move n away from %rdx

    mov (xp), %rax
    mul v
    sub %rax, (wp)
    adc $0, %rdx
    mov %rdx, %r8

    dec n
    jz L(ret)
    add $8, wp
    add $8, xp
    .align 16
L(top):
    mov (xp), %rax
    mul v
    add %r8, %rax
    adc $0, %rdx
    mov %rdx, %r8
    sub %rax, (wp)
    adc $0, %r8

    add $8, wp
    add $8, xp
    dec n
    jnz L(top)
L(ret):
    mov %r8, %rax
    ret
L(tmp):
    .size ramp_submul_1, L(tmp) - ramp_submul_1
    .cfi_endproc