nu 0.112.2

A new type of shell
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Cross-platform unzipping for artifacts
export def main [
  filename: string, # Name of file within zip to extract
  span: record # Span for error reporting
]: binary -> binary {
  # Store zip file to temporary file
  let zipfile = do {|file| save -fp $file; $file } (mktemp -t)

  let programs = [
    [preconditions, closure];
    [(which "gzip" | is-not-empty), { gzip $zipfile }]
    [((which "tar" | is-not-empty) and $nu.os-info.name == "windows"), { tar $zipfile $filename }]
    [(which "7z" | is-not-empty), { 7z $zipfile $filename }]
    [(which "unzip" | is-not-empty), { unzip $zipfile $filename }]
  ]

  # Attempt available programs
  for program in $programs {
    if not $program.preconditions {
      continue
    }

    try {
      let out = do $program.closure
      rm $zipfile
      return $out
    }
  }

  error make {
    msg: "Command not found"
    help: "Install one of the following programs: gzip, 7z, unzip, tar (Windows only)"
    label: {
      text: "failed to unzip artifact"
      span: $span
    }
  }

  # BUG: Unreachable echo to appease parse-time type checking
  echo
}

# tar can unzip files on Windows
def tar [zipfile: string, filename: string] {
  ^tar -Oxf $zipfile $filename
}

# Some versions of gzip can extract single files from zip files
def gzip [zipfile: string] {
  open -r $zipfile | ^gzip -d
}

# Use 7zip
def 7z [zipfile: string, filename: string] {
  ^7z x $zipfile -so $filename
}

# Use unzip tool (Info-ZIP, macOS, BSD)
def unzip [zipfile: string, filename: string] {
  ^unzip -p $zipfile $filename
}