nu 0.112.2

A new type of shell
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115

use std-rfc/iter only
use std/util null_device

# Get the workflow of the most recent commit with artifacts
export def get-workflow-run [commits: list<string>, span: record]: nothing -> int {
  mut latest = true
  for commit in ($commits | reverse) {
    let checks = (
      ^gh api $"/repos/nushell/nushell/commits/($commit)/check-runs"
      | from json
      | get check_runs
      | where name starts-with 'std-lib'
    )

    if ($checks | is-empty) {
      $latest = false
      continue
    }

    if not $latest {
      let short = $commit | str substring 0..6
      print $"(ansi yellow)Warning: using most recent commit with artifacts ($short), which is not the most recent on the PR(ansi reset)"
    }

    return (
      $checks
      | first
      | get html_url
      # parse workflow id from url to avoid another request
      | parse "https://github.com/nushell/nushell/actions/runs/{workflow_id}/job/{job_id}"
      | only workflow_id
    )
  }

  error make {
    msg: $"No artifacts"
    label: {
      text: $"no commits matching criteria have artifacts"
      span: $span
    }
    help: "Note that artifacts are deleted after 14 days"
  }

  # BUG: Unreachable echo to appease parse-time type checking
  echo
}

# Get artifacts associated with a PR
#
# Uses the latest commit if not specified
export def get-artifacts [
  number: record<item: int, span: record>
  platform: string
  span: record<start: int, end: int>
  --commit: string
] {
  # Make sure gh is available and has auth set up
  if (which ^gh | is-empty) {
    error make {
      msg: "Command not found"
      label: {
        text: "requires `gh`"
        span: $span
      }
      help: "Please install the `gh` commandline tool"
    }
  }

  try {
    ^gh auth status --hostname github.com o> $null_device
  } catch {
    error make {
      msg: "No authentication"
      label: {
        text: "requires GitHub authentication"
        span: $span
      }
      help: "Please run `gh auth login`"
    }
  }

  # Listing all artifacts requires pagination, which results in 8+ requests
  # Instead, we can do PR -> commit -> check runs -> artifacts which always is 4 requests

  # Get latest commit from PR (or use --commit)
  let commits = (
    ^gh pr view $number.item -R nushell/nushell --json commits
    | from json
    | get commits.oid
    | if $commit != null { where $it == $commit } else {}
  )

  let workflow_id = get-workflow-run $commits $number.span
  let artifacts = (
    ^gh api $"/repos/nushell/nushell/actions/runs/($workflow_id)/artifacts"
    | from json
    | get artifacts
    | into datetime created_at
    | sort-by -r created_at
    | where name == $"nu-($number.item)-($platform)"
  )

  if ($artifacts | is-empty) {
    error make {
      msg: $"No artifacts"
      label: {
        text: $"no artifacts for PR match criteria"
        span: $span
      }
      help: "Note that artifacts are deleted after 14 days"
    }
  }

  $artifacts
}