llama-cpp-sys-4 0.7.0

Low Level Bindings to llama.cpp
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

#version 450

#include "generic_head.glsl"
#include "types.glsl"

#extension GL_EXT_control_flow_attributes : enable

layout(constant_id = 0) const uint BLOCK_SIZE = 32;
layout(local_size_x_id = 0, local_size_y = 1, local_size_z = 1) in;

layout (binding = 0) readonly buffer G {A_TYPE data_g[];};
layout (binding = 1) readonly buffer X {B_TYPE data_x[];};
layout (binding = 2) readonly buffer Y {B_TYPE data_y[];};
layout (binding = 3) writeonly buffer D {D_TYPE data_d[];};

shared FLOAT_TYPE tmp[BLOCK_SIZE];

FLOAT_TYPE wg_reduce_max(FLOAT_TYPE v) {
    const uint tid = gl_LocalInvocationID.x;
    tmp[tid] = v;
    barrier();
    [[unroll]] for (uint s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
        if (tid < s) {
            tmp[tid] = max(tmp[tid], tmp[tid + s]);
        }
        barrier();
    }
    v = tmp[0];
    barrier();
    return v;
}

FLOAT_TYPE wg_reduce_sum(FLOAT_TYPE v) {
    const uint tid = gl_LocalInvocationID.x;
    tmp[tid] = v;
    barrier();
    [[unroll]] for (uint s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
        if (tid < s) {
            tmp[tid] += tmp[tid + s];
        }
        barrier();
    }
    v = tmp[0];
    barrier();
    return v;
}

void main() {
    const uint row = gl_WorkGroupID.z * 262144 + gl_WorkGroupID.y * 512 + gl_WorkGroupID.x;
    const uint tid = gl_LocalInvocationID.x;

    if (row >= p.KY) {
        return;
    }

    const uint off = row * p.KX;
    const FLOAT_TYPE d_by_nrows = FLOAT_TYPE(data_g[0]) / FLOAT_TYPE(p.KY);

    FLOAT_TYPE max_logit = FLOAT_TYPE(uintBitsToFloat(0xFF800000));
    for (uint i = tid; i < p.KX; i += BLOCK_SIZE) {
        max_logit = max(max_logit, FLOAT_TYPE(data_x[off + i]));
    }
    max_logit = wg_reduce_max(max_logit);

    FLOAT_TYPE sum_exp = FLOAT_TYPE(0.0f);
    for (uint i = tid; i < p.KX; i += BLOCK_SIZE) {
        sum_exp += exp(FLOAT_TYPE(data_x[off + i]) - max_logit);
    }
    const FLOAT_TYPE inv_sum = FLOAT_TYPE(1.0f) / wg_reduce_sum(sum_exp);

    for (uint i = tid; i < p.KX; i += BLOCK_SIZE) {
        const FLOAT_TYPE sm = exp(FLOAT_TYPE(data_x[off + i]) - max_logit) * inv_sum;
        data_d[off + i] = D_TYPE((sm - FLOAT_TYPE(data_y[off + i])) * d_by_nrows);
    }
}