liba 0.1.15

An algorithm library based on C/C++
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

#.rst:
# FindClangTidy
# -------------
#
# Find clang-tidy executable.
#
# Result Variables
# ^^^^^^^^^^^^^^^^
#
# This module defines the following variables:
#
# ``CLANG_TIDY_FOUND``, ``ClangTidy_FOUND``
#
# ``CLANG_TIDY_EXECUTABLE``
#
# ``CLANG_TIDY_VERSION``
#
# Functions
# ^^^^^^^^^
#
# .. command:: add_clang_tidy
#
#   ::
#
#     add_clang_tidy([OPTIONS opt] [TARGETS tgt ...] [tgt ...])
#
include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
find_program(CLANG_TIDY_EXECUTABLE NAMES clang-tidy)
mark_as_advanced(CLANG_TIDY_EXECUTABLE)

if(EXISTS "${CLANG_TIDY_EXECUTABLE}")
  execute_process(COMMAND ${CLANG_TIDY_EXECUTABLE} --version OUTPUT_VARIABLE CLANG_TIDY_VERSION)
  string(REGEX REPLACE ".*version ([^\n ]+).*" "\\1" CLANG_TIDY_VERSION "${CLANG_TIDY_VERSION}")
endif()

find_package_handle_standard_args(ClangTidy
  FOUND_VAR
    ClangTidy_FOUND
  REQUIRED_VARS
    CLANG_TIDY_EXECUTABLE
  VERSION_VAR
    CLANG_TIDY_VERSION
)

if(ClangTidy_FOUND)
  set(CLANG_TIDY_FOUND 1)
  function(add_clang_tidy)
    if(CMAKE_VERSION VERSION_LESS 3.6)
      return()
    endif()
    cmake_parse_arguments(CLANG_TIDY "" "" "TARGETS;OPTIONS" ${ARGN})
    list(APPEND CLANG_TIDY_TARGETS ${CLANG_TIDY_UNPARSED_ARGUMENTS})
    get_cmake_property(ENABLED_LANGUAGES ENABLED_LANGUAGES)
    foreach(LANG ${ENABLED_LANGUAGES})
      set_target_properties(${CLANG_TIDY_TARGETS} PROPERTIES ${LANG}_CLANG_TIDY "${CLANG_TIDY_EXECUTABLE};${CLANG_TIDY_OPTIONS}")
    endforeach()
  endfunction()
endif()