liba 0.1.15

An algorithm library based on C/C++
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

#.rst:
# FindClangFormat
# ---------------
#
# Find clang-format executable.
#
# Result Variables
# ^^^^^^^^^^^^^^^^
#
# This module defines the following variables:
#
# ``CLANG_FORMAT_FOUND``, ``ClangFormat_FOUND``
#
# ``CLANG_FORMAT_EXECUTABLE``
#
# ``CLANG_FORMAT_VERSION``
#
# Functions
# ^^^^^^^^^
#
# .. command:: add_clang_format
#
#   ::
#
#     add_clang_format(target [VERBOSE]
#         [WORKING_DIRECTORY dir] [COMMENT comment]
#         [OPTIONS opt ...] [SOURCES src ...] [src ...]
#     )
#
include(${CMAKE_ROOT}/Modules/FindPackageHandleStandardArgs.cmake)
find_program(CLANG_FORMAT_EXECUTABLE NAMES clang-format)
mark_as_advanced(CLANG_FORMAT_EXECUTABLE)

if(EXISTS "${CLANG_FORMAT_EXECUTABLE}")
  execute_process(COMMAND ${CLANG_FORMAT_EXECUTABLE} --version OUTPUT_VARIABLE CLANG_FORMAT_VERSION)
  string(REGEX REPLACE ".*version ([^\n ]+).*" "\\1" CLANG_FORMAT_VERSION "${CLANG_FORMAT_VERSION}")
endif()

find_package_handle_standard_args(ClangFormat
  FOUND_VAR
    ClangFormat_FOUND
  REQUIRED_VARS
    CLANG_FORMAT_EXECUTABLE
  VERSION_VAR
    CLANG_FORMAT_VERSION
)

if(ClangFormat_FOUND)
  set(CLANG_FORMAT_FOUND 1)
  function(add_clang_format target)
    cmake_parse_arguments(CLANG_FORMAT "VERBOSE" "WORKING_DIRECTORY;COMMENT" "SOURCES" ${ARGN})
    list(APPEND CLANG_FORMAT_SOURCES ${CLANG_FORMAT_UNPARSED_ARGUMENTS})
    list(APPEND CLANG_FORMAT_OPTIONS --style=file -i)
    if(CLANG_FORMAT_VERBOSE)
      list(INSERT CLANG_FORMAT_OPTIONS 0 --verbose)
    endif()
    if(NOT CLANG_FORMAT_WORKING_DIRECTORY)
      set(CLANG_FORMAT_WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
    endif()
    if(NOT CLANG_FORMAT_COMMENT)
      set(CLANG_FORMAT_COMMENT "Formatting ${target} using clang-format")
    endif()
    add_custom_target(${target} # https://clang.llvm.org/docs/ClangFormat.html
      ${CLANG_FORMAT_EXECUTABLE} ${CLANG_FORMAT_OPTIONS} ${CLANG_FORMAT_SOURCES}
      WORKING_DIRECTORY ${CLANG_FORMAT_WORKING_DIRECTORY}
      COMMENT "${CLANG_FORMAT_COMMENT}"
    )
  endfunction()
endif()