ferroui-native 0.3.0

The macOS platform of FerroUI: windows, input, clipboard, drag and drop, menus and Metal and OpenGL graphics over a native library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97

#include "common.h"

extern FrnDragDropEffects ConvertDragDropEffects(NSDragOperation nsop)
{
    int effects = 0;
    if((nsop & NSDragOperationCopy) != 0)
        effects |= (int)FrnDragDropEffects::Copy;
    if((nsop & NSDragOperationMove) != 0)
        effects |= (int)FrnDragDropEffects::Move;
    if((nsop & NSDragOperationLink) != 0)
        effects |= (int)FrnDragDropEffects::Link;
    return (FrnDragDropEffects)effects;
};

extern NSString* GetFrnCustomDataType()
{
    static NSString* result = nil;
    
    if (result == nil)
    {
        const size_t bufferSize = 256;
        char buffer[bufferSize];
        snprintf(buffer, bufferSize, "net.ferroui.inproc.uti.n%in", getpid());
        result = [NSString stringWithUTF8String:buffer];
    }
    
    return result;
}

@interface FrnDndSource : NSObject<NSDraggingSource>

@end

@implementation FrnDndSource
{
    NSDragOperation _operation;
    ComPtr<IFrnDndResultCallback> _cb;
    void* _sourceHandle;
};

- (NSDragOperation)draggingSession:(nonnull NSDraggingSession *)session sourceOperationMaskForDraggingContext:(NSDraggingContext)context
{
    return _operation;
}

- (FrnDndSource*) initWithOperation: (NSDragOperation)operation
                        andCallback: (IFrnDndResultCallback*) cb
                    andSourceHandle: (void*) handle
{
    self = [super init];
    _operation = operation;
    _cb = cb;
    _sourceHandle = handle;
    return self;
}

- (void)draggingSession:(NSDraggingSession *)session
           endedAtPoint:(NSPoint)screenPoint
              operation:(NSDragOperation)operation
{
    if(_cb != nil)
    {
        auto cb = _cb;
        _cb = nil;
        cb->OnDragAndDropComplete(ConvertDragDropEffects(operation));
    }
    if(_sourceHandle != nil)
    {
        FreeFrnGCHandle(_sourceHandle);
        _sourceHandle = nil;
    }
}

- (void*) gcHandle
{
    return _sourceHandle;
}

@end

extern NSObject<NSDraggingSource>* CreateDraggingSource(NSDragOperation op, IFrnDndResultCallback* cb, void* handle)
{
    return [[FrnDndSource alloc] initWithOperation:op andCallback:cb andSourceHandle:handle];
};

extern void* GetFrnDataObjectHandleFromDraggingInfo(NSObject<NSDraggingInfo>* info)
{
    id obj = [info draggingSource];
    if(obj == nil)
        return nil;
    if([obj isKindOfClass: [FrnDndSource class]])
    {
        auto src = (FrnDndSource*)obj;
        return [src gcHandle];
    }
    return nil;
}