zuzu-rust 0.6.0

Rust implementation of ZuzuScript
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126

from std/data/toon import TOON;
from std/data/json import JSON;
from test/more import *;

let fixture_json := new JSON( pairlists: true );
let binary_codec := new TOON( pairlists: true );
ok( binary_codec.encode_binarystring( { name: "Ada" } ) instanceof BinaryString, "encode_binarystring returns BinaryString" );
is(
	binary_codec.decode_binarystring( to_binary("name: café\n") ).get("name"),
	"café",
	"decode_binarystring decodes UTF-8 TOON bytes",
);

function _opt ( opts, String key, fallback ) {
	if ( opts ≡ null ) {
		return fallback;
	}
	if ( typeof opts ≡ "PairList" ) {
		return opts.has(key) ? opts.get(key) : fallback;
	}
	if ( typeof opts ≡ "Dict" ) {
		return opts.exists(key) ? opts.get(key) : fallback;
	}
	return fallback;
}

function _new_codec ( opts ) {
	return new TOON(
		indent: _opt( opts, "indent", 2 ),
		strict: _opt( opts, "strict", true ),
		delimiter: _opt( opts, "delimiter", "," ),
		pairlists: true,
		expandPaths: _opt( opts, "expandPaths", "off" ),
		keyFolding: _opt( opts, "keyFolding", "off" ),
		flattenDepth: _opt( opts, "flattenDepth", 999999 ),
	);
}

function _run_fixture_doc ( doc, String label ) {
	let category := doc.get("category");
	let tests := doc.get("tests");
	for ( const t in tests ) {

		subtest( `${label} - ${t.get("name")}`, function () {
			let opts := t.has("options") ? t.get("options") : null;
			let codec := _new_codec( opts );
			let should_error := t.has("shouldError") ? t.get("shouldError") : false;
			
			if ( category eq "decode" ) {
				if ( should_error ) {
					let e := exception( function () {
						codec.decode( t.get("input") );
					} );
					isnt( e, null, "exception thrown" );
				}
				else {
					let e := exception( function () {
						let got := codec.decode( t.get("input") );
						is( got, t.get("expected"), "decoded correctly" );
					} );
					is( e, null, "no exception thrown" );
				}
			}
			else {
				if ( should_error ) {
					let e := exception( function () {
						codec.encode( t.get("input") );
					} );
					isnt( e, null, "exception thrown" );
				}
				else {
					let e := exception( function () {
						let got := codec.encode( t.get("input") );
						is( got, t.get("expected"), "encoded correctly" );
					} );
					is( e, null, "no exception thrown" );
				}
			}
		} );
	}
}

_run_fixture_doc(
	fixture_json.decode(
		"""{
			"category": "decode",
			"tests": [
				{
					"name": "simple object",
					"input": "name: Ada\nage: 32\n",
					"expected": {
						"name": "Ada",
						"age": 32
					}
				},
				{
					"name": "strict malformed input",
					"input": "tags[2]: a,b,c",
					"shouldError": true
				}
			]
		}"""
	),
	"inline decode",
);

_run_fixture_doc(
	fixture_json.decode(
		"""{
			"category": "encode",
			"tests": [
				{
					"name": "simple object",
					"input": {
						"name": "Ada",
						"age": 32
					},
					"expected": "name: Ada\nage: 32"
				}
			]
		}"""
	),
	"inline encode",
);

done_testing();