zuzu-rust 0.6.0

Rust implementation of ZuzuScript
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149

from test/more import *;
requires_capability( "fs" );
requires_capability( "proc" );

from std/data/json import JSON;
from test/json_schema_fixtures import
	collect_optional_fixture_files,
	expected_optional_pass_count,
	fixture_context,
	fixture_relative_name,
	is_expected_optional_pass,
	run_fixture_file;

let context := fixture_context();
if ( context ≡ null ) {
	skip_all( "FIXTURE_DIR is not set" );
}

let fixture_root := context {fixture_root};
let loader := context {loader};

function _todo_fail ( String name ) {
	let old_todo := TODO;
	TODO := "optional fixture not yet required";
	fail(name);
	TODO := old_todo;
}

function _todo_is ( got, expected, String name ) {
	let old_todo := TODO;
	TODO := "optional fixture not yet required";
	is( got, expected, name );
	TODO := old_todo;
}

function report_required_optional_assertion (
	String kind,
	String name,
	String test_name,
	got,
	expected,
	err,
	Boolean failed,
) {
	if ( kind eq "diag" ) {
		diag(err);
	}
	else if ( kind eq "throw" ) {
		fail( name _ ": " _ test_name );
		diag( "threw: " _ err );
	}
	else {
		is( got, expected, name _ ": " _ test_name );
	}
}

function report_diagnostic_optional_assertion (
	String kind,
	String name,
	String test_name,
	got,
	expected,
	err,
	Boolean failed,
) {
	if ( kind eq "diag" ) {
		diag(err);
	}
	else if ( kind eq "throw" ) {
		_todo_fail( name _ ": " _ test_name );
		diag( "threw: " _ err );
	}
	else {
		_todo_is( got, expected, name _ ": " _ test_name );
	}
}

let optional_files := collect_optional_fixture_files(fixture_root);
is(
	optional_files.length(),
	34,
	"all optional draft2020-12 fixture files are covered",
);

let expected_optional_files := [];
let diagnostic_optional_files := [];
for ( let path in optional_files ) {
	let name := fixture_relative_name( fixture_root, path );
	if ( is_expected_optional_pass(name) ) {
		expected_optional_files.push(path);
	}
	else {
		diagnostic_optional_files.push(path);
	}
}

is(
	expected_optional_files.length(),
	expected_optional_pass_count(),
	"all expected-passing optional draft2020-12 fixture files are covered",
);

let json := new JSON();
let optional_ran := 0;
let expected_optional_ran := 0;
let expected_optional_failed := 0;

for ( let path in expected_optional_files ) {
	let name := fixture_relative_name( fixture_root, path );
	let result := run_fixture_file(
		json,
		loader,
		path,
		name,
		report_required_optional_assertion,
	);
	optional_ran += result {ran};
	expected_optional_ran += result {ran};
	expected_optional_failed += result {failed};
}

for ( let path in diagnostic_optional_files ) {
	let result := run_fixture_file(
		json,
		loader,
		path,
		fixture_relative_name( fixture_root, path ),
		report_diagnostic_optional_assertion,
	);
	optional_ran += result {ran};
}

is(
	expected_optional_failed,
	0,
	"all expected-passing optional draft2020-12 fixtures pass",
);

is(
	expected_optional_ran,
	400,
	"all expected-passing optional draft2020-12 fixture assertions ran",
);

diag(
	"Ran " _ optional_ran _ " optional JSON Schema draft2020-12 fixture assertions.",
);

done_testing();