zuzu-rust 0.2.0

Rust implementation of ZuzuScript
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

from std/eval import eval;
from std/math import Math;
from test/more import *;

let counter := 1;
is( eval("counter + 1;"), 2, "eval reads caller variables" );
eval("counter += 4;");
is( counter, 5, "eval assignment mutates existing caller variable" );

const String locked := "fixed";
let const_error := exception( function () {
	eval( "locked := \"changed\";" );
} );
ok(
	const_error instanceof Exception,
	"eval respects caller const bindings",
);
is( locked, "fixed", "failed eval assignment leaves caller const unchanged" );

eval("let eval_local := 42;");
let leak_error := exception( function () {
	eval("eval_local;");
} );
ok(
	leak_error instanceof Exception,
	"eval let declarations do not leak to caller scope",
);

let collision_result := null;
let collision_error := exception( function () {
	collision_result := eval(
		"from std/math import Math; Math.pi;"
	);
} );
ok(
	collision_error ≡ null,
	"eval imports do not collide with caller imports",
);
is(
	collision_result,
	Math.pi,
	"eval import collision expression still returns result",
);

eval("from std/string import split;");
let import_leak_error := exception( function () {
	eval( "split(\"a,b\", \",\");" );
} );
ok(
	import_leak_error instanceof Exception,
	"eval imports do not leak to caller scope",
);

eval("function eval_helper () { return 9; }");
let function_leak_error := exception( function () {
	eval("eval_helper();");
} );
ok(
	function_leak_error instanceof Exception,
	"eval function declarations do not leak to caller scope",
);

eval("class EvalLocalThing;");
let class_leak_error := exception( function () {
	eval("new EvalLocalThing();");
} );
ok(
	class_leak_error instanceof Exception,
	"eval class declarations do not leak to caller scope",
);

done_testing();