zenthra-text 0.2.2

Typography, font shaping, and text layout for the Zenthra UI framework
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

struct GlyphInstance {
    @location(0) pos: vec2<f32>,
    @location(1) size: vec2<f32>,
    @location(2) uv_pos: vec2<f32>,
    @location(3) uv_size: vec2<f32>,
    @location(4) color: vec4<f32>,
    @location(5) bg_color: vec4<f32>,
    @location(6) clip_rect: vec4<f32>,
};

struct VertexOutput {
    @builtin(position) clip_position: vec4<f32>,
    @location(0) uv: vec2<f32>,
    @location(1) color: vec4<f32>,
    @location(2) bg_color: vec4<f32>,
    @location(3) uv_size: vec2<f32>,
    @location(4) clip_rect: vec4<f32>,
};

@group(0) @binding(0)
var t_diffuse: texture_2d<f32>;
@group(0) @binding(1)
var s_diffuse: sampler;

@group(1) @binding(0)
var<uniform> screen_size: vec2<f32>;

@vertex
fn vs_main(
    @builtin(vertex_index) vertex_index: u32,
    instance: GlyphInstance,
) -> VertexOutput {
    var out: VertexOutput;
    
    var pos_quad = array<vec2<f32>, 4>(
        vec2<f32>(0.0, 0.0),
        vec2<f32>(1.0, 0.0),
        vec2<f32>(0.0, 1.0),
        vec2<f32>(1.0, 1.0),
    );
    
    let p = pos_quad[vertex_index];
    let world_pos = instance.pos + p * instance.size;
    
    let clip_x = (world_pos.x / screen_size.x) * 2.0 - 1.0;
    let clip_y = 1.0 - (world_pos.y / screen_size.y) * 2.0;
    
    out.clip_position = vec4<f32>(clip_x, clip_y, 0.0, 1.0);
    out.uv = instance.uv_pos + p * instance.uv_size;
    out.color = instance.color;
    out.bg_color = instance.bg_color;
    out.uv_size = instance.uv_size;
    out.clip_rect = instance.clip_rect;
    
    return out;
}

@fragment
fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
    // Hardware clipping
    if (in.clip_position.x < in.clip_rect.x || in.clip_position.x > in.clip_rect.x + in.clip_rect.z ||
        in.clip_position.y < in.clip_rect.y || in.clip_position.y > in.clip_rect.y + in.clip_rect.w) {
        discard;
    }

    // Detect solid color mode (used for continuous line highlights)
    if (in.uv_size.x < 0.00001 && in.uv_size.y < 0.00001) {
        return in.bg_color;
    }

    let tex_color = textureSample(t_diffuse, s_diffuse, in.uv);
    
    if (in.bg_color.a > 0.5) {
        return tex_color;
    } else {
        return vec4<f32>(in.color.rgb, in.color.a * tex_color.a);
    }
}