ydt 0.4.0

A simple command-line dictionary tool powered by Youdao
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

{ pkgs, gitignoreSource }:
let
  cargoToml = fromTOML (builtins.readFile ./Cargo.toml);
in
pkgs.rustPlatform.buildRustPackage {
  pname = cargoToml.package.name;
  version = cargoToml.package.version;
  src = gitignoreSource ./.;
  cargoLock = {
    lockFile = ./Cargo.lock;
  };
  outputs = [
    "out"
    "doc"
  ];

  postBuild = ''
    cargo doc --release --no-deps
  '';

  postInstall = ''
    docdir="$CARGO_TARGET_DIR/doc"
    if [ -z "$CARGO_TARGET_DIR" ]; then
      docdir="target/doc"
    fi
    if [ ! -d "$docdir" ]; then
      echo "doc directory not found: $docdir"
      exit 1
    fi
    mkdir -p "$doc/share/doc/$pname"
    cp -r "$docdir/." "$doc/share/doc/$pname/"
  '';

  meta = with pkgs.lib; {
    description = cargoToml.package.description;
    homepage = cargoToml.package.repository;
    license = licenses.mit;
    mainProgram = cargoToml.package.name;
    maintainers = [
      {
        name = "yushengyangchem";
        email = "yushengyangchem@gmail.com";
      }
    ];
  };
}