yaz-rs 0.1.0

Rust crate for Z39.50 using YAZ toolkit
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

{ pkgs ? import <nixpkgs> { } }:

let
  yaz = pkgs.stdenv.mkDerivation rec {
    pname = "yaz";
    version = "5.37.0";

    src = pkgs.fetchurl {
      url = "https://download.indexdata.com/pub/yaz/yaz-${version}.tar.gz";
      sha256 = "sha256-klf+sG4v27/Ot9BAwTn6E5V8TR67pqopOm3RPKsiJc4=";
    };

    nativeBuildInputs = with pkgs; [
      automake
      autoconf
      libtool
      pkg-config
    ];

    buildInputs = with pkgs; [
      libxml2
      libxslt
      icu
      readline
    ];

    configureFlags = [
      "--enable-shared"
      "--with-xml2"
      "--with-xslt"
      "--with-icu"
    ];

    meta = with pkgs.lib; {
      description = "Z39.50/SRU/Solr client and server";
      homepage = "https://www.indexdata.com/resources/software/yaz/";
      license = licenses.bsd3;
    };
  };
in
pkgs.mkShell {
  packages = with pkgs; [
    # Rust
    rustc
    cargo
    rustfmt
    clippy
    rust-analyzer
    pkg-config
    clang
    llvmPackages.libclang

    # Build tools for yaz
    automake
    autoconf
    libtool

    # yaz toolkit as defined above
    yaz
  ];

  # Required by bindgen
  LIBCLANG_PATH = pkgs.lib.makeLibraryPath [ pkgs.llvmPackages_latest.libclang.lib ];

  # Add YAZ to library and include paths
  LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath [ yaz ];
  PKG_CONFIG_PATH = "${yaz}/lib/pkgconfig:${pkgs.libxslt.dev}/lib/pkgconfig:${pkgs.libxml2.dev}/lib/pkgconfig";

  # Point rust-analyzer to the rust-src
  RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";

  shellHook = ''
    export RUST_BACKTRACE=1
  '';
}