xcodeproj 0.3.0

xcodeproj reader and parser.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

file    = { SOI ~ "// !$*UTF8*$!" ~ object ~ EOI }
object  = { "{" ~ field ~ (field)* ~ "}" | "{" ~ "}" }
field   = { key  ~ "=" ~ value ~ ";" }

key     = { uuid | ident | string  }
value   = {
     array
    | object
    | string
    | bool
    | kind
    | number
    | uuid
    | ident
}

array   = { "(" ~ value ~ ("," ~ value)* ~ ","? ~ ")" | "(" ~ ")" }
bool    = { (^"YES" | ^"NO") ~ !"_" ~ !ASCII_ALPHANUMERIC }
number  = @{ ASCII_DIGIT+ ~ ("." ~ ASCII_DIGIT+)* ~ !ASCII_ALPHA }
string  = @{ "\"" ~ INNER_STRING ~ "\"" }
ident   = @{
  (ASCII_ALPHA | ASCII_DIGIT | ("." | "/")* ~ ASCII_ALPHA{2}) ~ (ASCII_ALPHA | ASCII_DIGIT | "_" | "." | "/")*
}
uuid    = @{
  (ASCII_ALPHA{1} | ASCII_DIGIT{1}) ~ ASCII_ALPHANUMERIC{23} ~ !(ASCII_ALPHA | ".")
}
kind    = @{
     "PBXBuildFile"
    | "PBXFileReference"
    | "PBXLegacyTarget"
    | "PBXNativeTarget"
    | "PBXAggregateTarget"
    | "PBXProject"
    | "PBXGroup"
    | "PBXHeadersBuildPhase"
    | "PBXFrameworksBuildPhase"
    | "XCConfigurationList"
    | "PBXResourcesBuildPhase"
    | "PBXShellScriptBuildPhase"
    | "PBXSourcesBuildPhase"
    | "PBXTargetDependency"
    | "PBXVariantGroup"
    | "XCBuildConfiguration"
    | "PBXCopyFilesBuildPhase"
    | "PBXContainerItemProxy"
    | "XCVersionGroup"
    | "PBXRezBuildPhase"
    | "PBXBuildRule"
    | "XCRemoteSwiftPackageReference"
    | "XCSwiftPackageProductDependency"
}


escape  = @{ "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t" | unicode) }
unicode = @{ "u" ~ (ASCII_HEX_DIGIT{4} | ASCII_HEX_DIGIT{3} ~ ASCII_ALPHA) }

INNER_STRING   = _{ (!("\"" | "\\") ~ ANY)* ~ (escape ~ INNER_STRING)? }
WHITESPACE = _{ " " | "\t" | "\r" | "\n" | ("\\" ~ unicode) }
COMMENT = _{ "/*" ~ (!"*/" ~ ANY)* ~ "*/" }