wt-core 0.3.1

Portable Git worktree lifecycle manager
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

{
  description = "wt-core — portable Git worktree lifecycle manager";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          fs = pkgs.lib.fileset;
          src = fs.toSource {
            root = ./.;
            fileset = fs.unions [
              ./Cargo.toml
              ./Cargo.lock
              ./src
              ./tests
              ./bindings
            ];
          };
        in
        {
          default = pkgs.rustPlatform.buildRustPackage {
            pname = "wt-core";
            version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.version;

            inherit src;

            cargoLock.lockFile = ./Cargo.lock;

            nativeBuildInputs = [ pkgs.git pkgs.makeWrapper ];

            postInstall = ''
              mkdir -p $out/share/wt-core
              cp -r bindings $out/share/wt-core/bindings
              wrapProgram $out/bin/wt-core \
                --prefix PATH : ${pkgs.lib.makeBinPath [ pkgs.git ]}
            '';

            meta = with pkgs.lib; {
              description = "Portable Git worktree lifecycle manager";
              homepage = "https://github.com/kioku/wt-core";
              license = licenses.mit;
              mainProgram = "wt-core";
            };
          };
        });

      devShells = forAllSystems (system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.mkShell {
            buildInputs = [
              pkgs.cargo
              pkgs.rustc
              pkgs.clippy
              pkgs.rustfmt
              pkgs.git
            ];
          };
        });
    };
}