writefreely_client 0.1.0

WriteFreely API client library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118

# SPDX-FileCopyrightText: 2023 Gergely Nagy
# SPDX-FileContributor: Gergely Nagy
#
# SPDX-License-Identifier: EUPL-1.2
{
  description = "Rust API client for WriteFreely";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.05";
    systems.url = "github:nix-systems/default";
    flake-parts.url = "github:hercules-ci/flake-parts";

    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.nixpkgs-stable.follows = "nixpkgs";
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    naersk = {
      url = "github:nix-community/naersk/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {flake-parts, ...}:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = import inputs.systems;
      imports = [
        inputs.pre-commit-hooks.flakeModule
        inputs.treefmt-nix.flakeModule
      ];
      perSystem = {
        system,
        config,
        pkgs,
        ...
      }: let
        toolchain = pkgs.rust-bin.stable.latest.default;
        naersk-lib = pkgs.callPackage inputs.naersk {
          cargo = toolchain;
          rustc = toolchain;
        };
      in {
        _module.args.pkgs = import inputs.nixpkgs {
          inherit system;
          overlays = [
            inputs.rust-overlay.overlays.default
          ];
        };
        pre-commit = {
          settings.hooks = {
            treefmt = {
              enable = true;
              always_run = true;
            };
            reuse = {
              enable = true;
              name = "reuse";
              description = "Run REUSE compliance tests";
              entry = "${pkgs.reuse}/bin/reuse lint";
              pass_filenames = false;
              always_run = true;
            };
          };
        };
        treefmt.config = {
          projectRootFile = "Cargo.toml";
          programs = {
            alejandra.enable = true; # nix
            statix.enable = true; # nix static analysis
            deadnix.enable = true; # find dead nix code
            rustfmt.enable = true; # rust
            shellcheck.enable = true; # bash/shell
            taplo.enable = true; # toml
          };
        };
        devShells = {
          default = pkgs.mkShell {
            nativeBuildInputs = with pkgs; [
              cargo-tarpaulin
              reuse
              toolchain
            ];
            inputsFrom = [
              config.pre-commit.devShell
              config.treefmt.build.devShell
            ];

            shellHook = ''
              export CARGO_HOME=$(pwd)/.cargo
            '';
          };
        };
        packages = {
          default = config.packages.writefreely_client;
          writefreely_client = naersk-lib.buildPackage {
            pname = "writefreely_client";
            src = ./.;
            meta.description = "Rust API client for WriteFreely";
          };
          coverage = pkgs.writeShellApplication {
            name = "coverage";
            runtimeInputs = [pkgs.cargo-tarpaulin];
            text = ''
              cargo tarpaulin --features integration-tests --profile=tarpaulin --out Html
            '';
          };
        };
      };
    };
}