woxi 0.1.0

Interpreter for a subset of the Wolfram Language
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }
COMMENT = _{ "(*" ~ (!"*)" ~ ANY)* ~ "*)" }

PartExtract = { Identifier ~ "[[" ~ Expression ~ "]]" }

Integer = @{ ("-")? ~ ASCII_DIGIT+ }
Real = @{ ("-")? ~ ASCII_DIGIT+ ~ "." ~ ASCII_DIGIT+ }
Constant = { ("-")? ~ "Pi" }
NumericValue = { Real | Integer | Constant }

Identifier = @{ (ASCII_ALPHA | "_") ~ (ASCII_ALPHANUMERIC | "_")* }
String = @{ "\"" ~ (!"\"" ~ ANY)* ~ "\"" }

// Special functions
SpecialFunction = { "Sin" | "Cos" | "Tan" | "Plot" | "Prime" | "GroupBy" | "Print" }
FunctionCall = { (Identifier | SpecialFunction | AnonymousFunction) ~ "[" ~ (Expression ~ ("," ~ (Expression | List))*)? ~ "]" }

// Anonymous function syntax
Slot = @{ "#" ~ ASCII_DIGIT* }
AnonymousFunction = { Slot ~ (Operator ~ Term)? ~ "&" }

Operator = {
    "/@"     // keep first
  | "==" | "!="
  | "<=" | ">="
  | ":="
  | "+" | "-" | "*" | "/" | "^"
  | "<" | ">"
  | "=" | "@"
}

PostfixApplication = { Term ~ "//" ~ Identifier }
Expression = { PostfixApplication | Term ~ (Operator ~ Term)* }
Term = _{
    PartExtract
  | NumericValue
  | Constant
  | String
  | List
  | FunctionCall
  | Identifier
  | AnonymousFunction
  | Slot
  | Association
  | "(" ~ Expression ~ ")"
}

List = { "{" ~ (Expression ~ ("," ~ Expression)*)? ~ "}" }
Pattern = { Identifier ~ "_" }

AssociationItem = { Expression ~ "->" ~ Expression }
Association     = { "<|" ~ ( AssociationItem ~ ("," ~ AssociationItem)* )? ~ "|>" }

FunctionDefinition = { Identifier ~ "[" ~ Pattern ~ "]" ~ ":=" ~ Expression }

Statement = _{ FunctionDefinition | Expression }

Program = { SOI ~ Statement ~ (";" ~ Statement)* ~ EOI }