wls-alloc 0.4.0

Constrained least-squares control allocator for flight controllers (no_std, stack-only)
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# wls-alloc development tasks

# List available recipes
default:
    @just --list

# Run the full test suite
test:
    cargo test

# Run only the C golden-data compliance tests (1000 cases, 5 checks)
golden:
    cargo test --test regression -- --nocapture

# Run a single named C compliance test
# e.g.: just golden-one all_cases_incremental_vs_c_ref
golden-one name:
    cargo test --test regression -- --nocapture {{ name }}

# Run edge-case and unregularised tests (no C reference data)
unit:
    cargo test --test edge_cases --test unreg

# Run doc-tests only
doctest:
    cargo test --doc

# Clippy (matches CI: deny all warnings)
lint:
    cargo clippy --all-targets -- -D warnings

# Format check (matches CI)
fmt:
    cargo fmt --check

# Apply formatting
fmt-fix:
    cargo fmt

# Full CI gate: fmt + lint + test + doc
ci: fmt lint test
    RUSTDOCFLAGS="-D warnings" cargo doc --no-deps

# Verify the library builds for embedded (no_std, thumbv7em)
no-std:
    cargo build --target thumbv7em-none-eabihf --lib

# Run benchmarks
bench:
    cargo bench