whiley_test_file 0.6.2

An API for manipulating test files for the Whiley Programming Language.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

original.name="Property_Valid_21"
======
>>> main.whiley
// This benchmark was created specifically to test recursive
// properties.
type Node is {int data, List next}
type List is null|Node

// A given (sub)list is "reachable" from its enclosing list
property reachable(List head, List child) -> (bool r):
    // Either we met the child, or need to keep searching
    return (head == child) || (head is Node && reachable(head.next,child))

// Lemma is needed to go "against" the direction of unrolling.  This
// may seem kind of strange.
function lemma(List head, List child)
// If head ~~> child
requires reachable(head,child)
// Then, head ~~> child.next
ensures (child is null) || reachable(head,child.next):
    //
    if head != child:
        assert head is Node
        lemma(head.next,child)

// Determine length of a list
function len(List l) -> (int r):
    //
    int x = 0
    List ol = l // ghost
    // iterate until 
    while l is Node
    where l is null || reachable(ol,l):
        lemma(ol,l)
        l = l.next
        x = x + 1
    //
    return x

public export method test():
    // List of length 1
    List l1 = {data: 0, next: null}
    // List of length 2
    List l2 = {data: 0, next: l1}
    // List of length 3
    List l3 = {data: 0, next: l2}
    //
    assume len(null) == 0
    //
    assume len(l1) == 1
    //
    assume len(l2) == 2
    //
    assume len(l3) == 3

---