wasm-wave 0.263.0

WebAssembly Value Encoding
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95

# WAVE EBNF

A WAVE value is defined by the `value` rule below. Many applications may allow
whitespace around the value, equivalent to the `value-ws` rule.

> Note that Bool, Variant, Enum, Option and Result values are combined under
> the `variant-case` rule because these cannot be distinguished without type
> information. Likewise, Record and Map values are combined under the
> `record-or-map` rule, and `empty-braces` (`{}`) may be empty Flags or an
> empty Map (`{:}` may also be an empty Map).

```ebnf
value ::= number
        | char
        | string
        | multiline-string
        | variant-case
        | tuple
        | list
        | empty-braces
        | flags
        | record-or-map

value-ws ::= ws value ws
ws ::= ([ \t\n\r] | comment)*
comment ::= '//' [^\n]*

number ::= number_finite
         | 'nan'
         | 'inf'
         | '-inf'
number_finite ::= integer number-fraction? number-exponent?
integer ::= unsigned-integer
          | '-' unsigned-integer
unsigned-integer ::= '0'
                   | [1-9] [0-9]*
number-fraction ::= '.' [0-9]+
number-exponent ::= [eE] [+-]? [0-9]+

char ::= ['] char-char [']
char-char ::= common-char | '"'

string ::= '"' string-char* '"'
string-char ::= common-char | [']

multiline-string ::= '"""' line-break multiline-string-line* [ ]* '"""'
multiline-string-line ::= [ ]* multiline-string-char* line-break
multiline-string-char ::= common-char | ['"]

line-break ::= '\r\n' | '\n'

common-char ::= <any Unicode Scalar Value except ['"\n\\]>
              | '\' escape
escape ::= ['"tnr\\] | escape-unicode
escape-unicode ::= 'u{' [0-9a-fA-F]+ '}'

variant-case ::= label ws variant-case-payload?
variant-case-payload ::= '(' value-ws ')'

tuple ::= '(' values-seq ','? ws ')'

list ::= '[' ws ']'
       | '[' values-seq ','? ws ']'

values-seq ::= value-ws
             | values-seq ',' value-ws

empty-braces ::= '{' ws '}'

flags ::= '{' flags-seq ','? ws '}'
flags-seq ::= ws label ws
            | flags-seq ',' ws label ws

record-or-map ::= '{' ws ':' ws '}'
                | '{' entries ','? ws '}'
entries ::= ws entry ws
          | entries ',' ws entry ws
entry ::= entry-key ws ':' ws value
entry-key ::= label
            | number
            | char
            | string
            | multiline-string

label ::= '%'? first-word ('-' word)*
first-word ::= [a-z][a-z0-9]*
             | [A-Z][A-Z0-9]*
word ::= [a-z0-9]+
       | [A-Z0-9]+
```

* "`Unicode scalar value`" is defined by Unicode
* `escape-unicode` must identify a valid Unicode scalar value, using 1 to 6 hexadecimal digits.
* `multiline-string-line` must not contain `"""`
* See [README.md#multiline-strings](./README.md#multiline-strings) for the indentation and decoding rules that constrain `multiline-string`.