vmw_backdoor 0.2.4

A pure-Rust library for VMware host-guest protocol ("VMXh backdoor")
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156

.text

# fn _vmw_backdoor_lb_in(arg: &BackdoorBuf, res: &mut BackdoorBuf);
.global _vmw_backdoor_lb_in
_vmw_backdoor_lb_in:
  # Preserve caller values.
  movq %rbx, %r8;
  movq %rbp, %r9;
  movq %rdi, %r10;
  movq %rsi, %r11;

  movl 0(%r10), %eax;
  movl 4(%r10), %ebx;
  movl 8(%r10), %ecx;
  movl 12(%r10), %edx;
  movl 16(%r10), %ebp;
  movl 20(%r10), %edi;
  movl 24(%r10), %esi;

  # Backdoor call.
  inl  %dx, %eax;

  # Record results.
  movl %eax, 0(%r11);
  movl %ebx, 4(%r11);
  movl %ecx, 8(%r11);
  movl %edx, 12(%r11);
  movl %ebp, 16(%r11);
  movl %edi, 20(%r11);
  movl %esi, 24(%r11);

  # Restore caller values.
  movq %r8, %rbx;
  movq %r9, %rbp;

  # Return.
  xor %rax, %rax;
  ret;

# fn _vmw_backdoor_lb_out(arg: &BackdoorBuf, res: &mut BackdoorBuf);
.global _vmw_backdoor_lb_out
_vmw_backdoor_lb_out:
  # Preserve caller values.
  movq %rbx, %r8;
  movq %rbp, %r9;
  movq %rdi, %r10;
  movq %rsi, %r11;

  # Magic number.
  movl 0(%r10), %eax;
  movl 4(%r10), %ebx;
  # Command.
  movl 8(%r10), %ecx;
  # I/O port (low-bandwidth).
  movl 12(%r10), %edx;
  movl 16(%r10), %ebp;
  movl 20(%r10), %edi;
  movl 24(%r10), %esi;

	# Backdoor call.
  outl  %eax, %dx;

  # Record results.
  movl %eax, 0(%r11);
  movl %ebx, 4(%r11);
  movl %ecx, 8(%r11);
  movl %edx, 12(%r11);
  movl %ebp, 16(%r11);
  movl %edi, 20(%r11);
  movl %esi, 24(%r11);

  # Restore caller values.
  movq %r8, %rbx;
  movq %r9, %rbp;

  # Return.
  xor %rax, %rax;
  ret;

# fn _vmw_backdoor_hb_out(arg: &Buf, cmd: &mut Buf);
.global _vmw_backdoor_hb_out
_vmw_backdoor_hb_out:
	  # Preserve caller values.
	  movq %rbx, %r8;
	  movq %rbp, %r9;
	  movq %rdi, %r10;
	  movq %rsi, %r11;

	  movl 0(%r10), %eax;
	  movl 4(%r10), %ebx;
	  movl 8(%r10), %ecx;
	  movl 12(%r10), %edx;
	  movl 16(%r10), %ebp;
	  movq 20(%r10), %rdi;
	  movq 28(%r10), %rsi;

    # Backdoor call.
    cld;
    rep;
    outsb;

	  # Record results.
	  movl %eax, 0(%r11);
	  movl %ebx, 4(%r11);
	  movl %ecx, 8(%r11);
	  movl %edx, 12(%r11);
	  movl %ebp, 16(%r11);
	  movq %rdi, 20(%r11);
	  movq %rsi, 28(%r11);

	  # Restore caller values.
	  movq %r8, %rbx;
	  movq %r9, %rbp;

	  # Return.
  	xor %rax, %rax;
	  ret;

# fn _vmw_backdoor_hb_in(arg: &Buf, cmd: &mut Buf);
.global _vmw_backdoor_hb_in
_vmw_backdoor_hb_in:
	  # Preserve caller values.
	  movq %rbx, %r8;
	  movq %rbp, %r9;
	  movq %rdi, %r10;
	  movq %rsi, %r11;

	  movl 0(%r10), %eax;
	  movl 4(%r10), %ebx;
	  movl 8(%r10), %ecx;
	  movl 12(%r10), %edx;
	  movl 16(%r10), %ebp;
	  movq 20(%r10), %rdi;
	  movq 28(%r10), %rsi;

    # Backdoor call.
    cld;
	  rep;
	  insb;

	  # Record results.
	  movl %eax, 0(%r11);
	  movl %ebx, 4(%r11);
	  movl %ecx, 8(%r11);
	  movl %edx, 12(%r11);
	  movl %ebp, 16(%r11);
	  movq %rdi, 20(%r11);
	  movq %rsi, 28(%r11);

	  # Restore caller values.
	  movq %r8, %rbx;
	  movq %r9, %rbp;

 	  # Return.
  	xor %rax, %rax;
	  ret;