vibelang 0.1.1

Programmatically instantiate Web Agents from Vibelang files
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }
COMMENT = _{ "//" ~ (!("\r" | "\n") ~ ANY)* }

Identifier = @{ (ASCII_ALPHA | "_") ~ (ASCII_ALPHANUMERIC | "_")* }
StringLiteral = @{ "\"" ~ (!"\"" ~ ANY)* ~ "\"" }
IntLiteral = @{ "-"? ~ ASCII_DIGIT+ }
FloatLiteral = @{ "-"? ~ ASCII_DIGIT+ ~ "." ~ ASCII_DIGIT+ }
BoolLiteral = @{ "true" | "false" }

Program = { SOI ~ Declaration* ~ EOI }

Declaration = { FunctionDecl | TypeDecl | ClassDecl }

Type = { MeaningType | BasicType }
BasicType = { Identifier }
MeaningType = { "Meaning" ~ "<" ~ Type ~ ">" ~ "(" ~ StringLiteral ~ ")" }

TypeDecl = { "type" ~ Identifier ~ "=" ~ Type ~ ";" }
ClassDecl = { "class" ~ Identifier ~ "{" ~ (MemberVar | FunctionDecl)* ~ "}"}
MemberVar = { Identifier ~ ":" ~ Type ~ ";" }

FunctionDecl = { "fn" ~ Identifier ~ "(" ~ ParamList? ~ ")" ~ ("->" ~ Type)? ~ Block }
ParamList = { Parameter ~ ("," ~ Parameter)* }
Parameter = { Identifier ~ ":" ~ Type }

Block = { "{" ~ Statement* ~ "}" }
Statement = { VarDecl | ReturnStmt | PromptStmt | ExprStmt }
PromptStmt = { "prompt" ~ StringLiteral ~ ";" }

VarDecl = { "let" ~ Identifier ~ (":" ~ Type)? ~ "=" ~ Expression ~ ";" }
ReturnStmt = { "return" ~ Expression? ~ ";" }
ExprStmt = { Expression ~ ";" }

Expression = { CallExpr | Literal | Identifier }
CallExpr = { Identifier ~ "(" ~ (Expression ~ ("," ~ Expression)*)? ~ ")" }
Literal = { StringLiteral | IntLiteral | FloatLiteral | BoolLiteral }