veloci 0.3.3

Veloci Redactor: redact secrets and PII from text and structured files, with stable numbered redactions
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84

{
  description = "Veloci Redactor: redact secrets and PII from text and structured files";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs =
    { self, nixpkgs }:
    let
      inherit (nixpkgs) lib;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forEachSystem = f: lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});

      mkPackage =
        pkgs:
        pkgs.rustPlatform.buildRustPackage {
          pname = "veloci";
          version = "0.3.2";

          src = lib.cleanSourceWith {
            src = ./.;
            filter =
              path: type:
              let
                rel = lib.removePrefix (toString ./. + "/") (toString path);
              in
              lib.cleanSourceFilter path type
              && rel != "target"
              && !lib.hasPrefix "target/" rel
              && !lib.hasPrefix "plugin/libexec" rel
              && !lib.hasPrefix "result" rel;
          };

          cargoLock.lockFile = ./Cargo.lock;

          # aws-lc-sys (via hf-hub / reqwest) and onig_sys need a C toolchain.
          nativeBuildInputs = [
            pkgs.cmake
            pkgs.pkg-config
            pkgs.rustPlatform.bindgenHook
          ];

          cargoBuildFlags = [ "--package" "veloci-cli" ];
          cargoTestFlags = [ "--workspace" ];

          meta = {
            description = "Redact secrets and PII from text and structured files";
            homepage = "https://github.com/phayes/velociredactor";
            license = lib.licenses.mit;
            mainProgram = "veloci";
          };
        };
    in
    {
      packages = forEachSystem (pkgs: rec {
        veloci = mkPackage pkgs;
        default = veloci;
      });

      apps = forEachSystem (pkgs: {
        default = {
          type = "app";
          program = lib.getExe self.packages.${pkgs.system}.default;
        };
      });

      devShells = forEachSystem (pkgs: {
        default = pkgs.mkShell {
          inputsFrom = [ self.packages.${pkgs.system}.default ];
          packages = [
            pkgs.cargo
            pkgs.rustc
            pkgs.rustfmt
            pkgs.clippy
            pkgs.rust-analyzer
          ];
        };
      });
    };
}