valu3 0.9.6

A generic serialization/deserialization/type framework
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24

json           = _{ SOI ~ (object | array | string | number | boolean | null) ~ EOI }
WHITESPACE     = _{ " " | "\t" | "\r" | "\n" }
object         =  {
    ("#{" | "{") ~ "}"
  | ("#{" | "{") ~ key_value_pair ~ ("," ~ key_value_pair)* ~ "}"
}
key_value_pair =  { string ~ ":" ~ value }
array          =  {
    "[" ~ "]"
  | "[" ~ value ~ ("," ~ value)* ~ "]"
}
value          = _{ object | array | string | number | boolean | null }
boolean        =  { "true" | "false" }
null           =  { "null" }
string         = ${ "\"" ~ inner ~ "\"" }
inner          = @{ char* }
char           =  {
    !("\"" | "\\") ~ ANY
  | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t")
  | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}
number         = @{
    "-"? ~ ("0" | ASCII_NONZERO_DIGIT ~ ASCII_DIGIT*) ~ ("." ~ ASCII_DIGIT*)? ~ (^"e" ~ ("+" | "-")? ~ ASCII_DIGIT+)?
}