utf8proc 0.1.2

Rust bindings to the utf8proc library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

check: && spellcheck check-format
    ruff check
    uvx mypy --strict scripts/verify_cargo_inheritance.py
    python3 scripts/verify_cargo_inheritance.py
    cargo deny --workspace check all
    cargo clippy --workspace
    cargo doc --workspace --no-deps
    cargo rdme --check
    cargo xtask bindgen --check

fix: format
    # failure to apply one fix will not affect the others
    -ruff check --fix --unsafe-fixes
    -cargo clippy --workspace --fix --allow-staged --allow-dirty
    -just regen
    -cargo rdme --force
    # final status is equivalent to `check`
    just check


regen:
    cargo xtask bindgen

format:
    cargo fmt
    ruff format
    ruff check --select=I --fix
    taplo format

check-format:
    cargo fmt --check
    ruff format --check
    ruff check --select=I
    taplo format --check

spellcheck:
    -just _typos

spellfix:
    # typos --write-changes
    -just _typos --write-changes

# run typos, pinned to an appropriate minor version
_typos *flags:
    @uvx typos@1.34.0 {{flags}}