unpm 0.2.0

Lightweight vendoring of static assets. No node_modules, no runtime fetching.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
  };

  outputs = { self, nixpkgs }:
    let
      forAllSystems = nixpkgs.lib.genAttrs [ "aarch64-darwin" "x86_64-linux" ];

      traceyVersion = "1.3.0";
      traceySources = {
        aarch64-darwin = {
          url = "https://github.com/bearcove/tracey/releases/download/v${traceyVersion}/tracey-aarch64-apple-darwin.tar.xz";
          hash = "sha256-NltLMFbFiZAVJrVEAbI2NEMKkl/LEyf1zW9TVoY7INU=";
        };
        x86_64-linux = {
          url = "https://github.com/bearcove/tracey/releases/download/v${traceyVersion}/tracey-x86_64-unknown-linux-gnu.tar.xz";
          hash = "sha256-+8DCXEQyjMsJcLJQkJX/KUEvpyy7xrADbEzujBKCH0c=";
        };
      };
    in {
      overlays.default = final: prev: {
        unpm = final.rustPlatform.buildRustPackage {
          pname = "unpm";
          version = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package.version;
          src = self;
          cargoLock.lockFile = ./Cargo.lock;
        };

        tracey = let
          src = traceySources.${final.stdenv.hostPlatform.system}
            or (throw "tracey: unsupported system ${final.stdenv.hostPlatform.system}");
        in final.stdenv.mkDerivation {
          pname = "tracey";
          version = traceyVersion;
          src = final.fetchurl { inherit (src) url hash; };
          nativeBuildInputs = [ final.xz ];
          sourceRoot = ".";
          unpackPhase = ''
            tar xf $src
          '';
          installPhase = ''
            install -Dm755 tracey-*/tracey $out/bin/tracey
          '';
        };
      };

      packages = forAllSystems (system:
        let pkgs = import nixpkgs { inherit system; overlays = [ self.overlays.default ]; };
        in {
          default = pkgs.unpm;
          tracey = pkgs.tracey;
        }
      );

      devShells = forAllSystems (system:
        let pkgs = import nixpkgs { inherit system; overlays = [ self.overlays.default ]; };
        in {
          default = pkgs.mkShell {
            packages = [ pkgs.tracey ];
          };
        }
      );
    };
}