# Range
⍤⤙≍ [0 1 2 3 4 5] ⇡6
⍤⤙≍ [¯1 ¯2 ¯3 ¯4 ¯5 ¯6] ⇡¯6
⍤⤙≍ [[0_0 0_1 0_2] [1_0 1_1 1_2] [2_0 2_1 2_2]] ⇡3_3
⍤⤙≍ [[0_0 0_1 0_2] [1_0 1_1 1_2]] ⇡2_3
⍤⤙≍ [[¯1_0 ¯1_1 ¯1_2] [¯2_0 ¯2_1 ¯2_2]] ⇡¯2_3
⍤⤙≍ [5 6 7 8 9] +5⇡5
⍤⤙≍ [4 3 2 1 0] +5⇡¯5
# Subscripted range
⍤⤙≍ [1 2 3 4 5] ⇡₁5
⍤⤙≍ [5] ⇡₅5
⍤⤙≍ [] ⇡₅4
⍤⤙≍ [¯1 0 1 2 3 4 5] ⇡₋₁5
⍤⤙≍ [¯3 ¯2 ¯1 0 1 2] ⇡₋₃2
⍤⤙≍ [[1_1 1_2] [2_1 2_2]] ⇡₁2_2
⍤⤙≍ [[¯1_¯1 ¯1_0 ¯1_1] [0_¯1 0_0 0_1] [1_¯1 1_0 1_1]] ⇡₋₁1_1
⍤⤙≍ ⊃(↘-1⊙(+1⇡))⋅⇡₁₀₀ 100 1e3
⍤⤙≍ [1/2 3/2 5/2 7/2] +1/2 ⇡4
⍤⤙≍ °△ 0_0_2 ⇡₅2_3
⍤⤙≍ °△ 6_0_2 ⇡₅10_4
⍤⤙≍ °△ 0_4_2 ⇡₅3_8
# Deshape
⍤⤙≍ [5] ♭5
⍤⤙≍ [5] ♭[5]
⍤⤙≍ [5] ♭[[5]]
⍤⤙≍ [1 2 3] ♭ [1 2 3]
⍤⤙≍ [1 2 3 4] ♭ [1_2 3_4]
⍤⤙≍ ⊃(□₁|♭□)°△2_3_4
# Subscripted deshape
⍤⤙≍ [] △ ♭₀ ↯2_3_4_5⇡120
⍤⤙≍ [120] △ ♭₁ ↯2_3_4_5⇡120
⍤⤙≍ [24 5] △ ♭₂ ↯2_3_4_5⇡120
⍤⤙≍ [6 4 5] △ ♭₃ ↯2_3_4_5⇡120
⍤⤙≍ [2 3 4 5] △ ♭₄ ↯2_3_4_5⇡120
⍤⤙≍ [1 2 3 4 5] △ ♭₅ ↯2_3_4_5⇡120
⍤⤙≍ [1 1 2 3 4 5] △ ♭₆ ↯2_3_4_5⇡120
⍤⤙≍ [6 4 5] △ ♭₋₁ ↯2_3_4_5⇡120
⍤⤙≍ [24 5] △ ♭₋₂ ↯2_3_4_5⇡120
⍤⤙≍ [120] △ ♭₋₃ ↯2_3_4_5⇡120
⍤⤙≍ [3 4] ⍜°△≡♭₁ 3_4
⍤⤙≍ [3 1 4] ⍜°△≡♭₂ 3_4
⍤⤙≍ [3 1 1 4] ⍜°△≡♭₃ 3_4
⍤⤙≍ [3 1 1 1 4] ⍜°△≡♭₄ 3_4
# Reverse
⍤⤙≍ 5 ⇌5
⍤⤙≍ [3 2 1] ⇌[1 2 3]
⍤⤙≍ [5_6 3_4 1_2] ⇌[1_2 3_4 5_6]
# Transpose
⍤⤙≍ 5 ⍉5
⍤⤙≍ [1 2 3] ⍉[1 2 3]
⍤⤙≍ [1_4 2_5 3_6] ⍉[1_2_3 4_5_6]
⍤⤙≍ ⟜(⍉⍉)↯3_4⇡12
⍤⤙≍ ⟜(°⍉⍉)↯3_4⇡12
⍤⤙≍ [[0_1 0_0] [0_1 1_1] [0_1 2_2]] ⍉⇡2_3
⍤⤙≍ [[0_0_0 1_1_1] [0_1_2 0_1_2]] ⍉⍉⇡2_3
⍤⤙≍ [[0_0_0 1_1_1] [0_1_2 0_1_2]] °⍉⇡2_3
⍤⤙≍ ⊃(⍉⍉)°⍉ ↯2_3_4⇡24
⍤⤙≍ ⊃°(⍉⍉)⍉ ↯2_3_4⇡24
⍤⤙≍ ⊃(⍉⍉)°(⍉⍉) ↯2_3_4_5⇡120
⍤⤙≍ ⊃°(⍉⍉)(⍉⍉) ↯2_3_4_5⇡120
⍤⤙≍ ⊃⍉°(⍉⍉⍉) ↯2_3_4_5⇡120
⍤⤙≍ ⊃°⍉(⍉⍉⍉) ↯2_3_4_5⇡120
⍤⤙≍ ⟜(⍉⍉⍉⍉) ↯2_3_4_5⇡120
⍤⤙≍ □[1_3 2_4] ⍚⍉□[1_2 3_4]
⍤⤙≍ {[1_3 2_4] [5_7 6_8]} ⍚⍉{[1_2 3_4] [5_6 7_8]}
⍤⤙≍ ⊃⍜⍉⇌⍜(⍉⍉⍉)⇌ [[1 2 3] [4 5 6] [7 8 9]]
# Subscripted length
⍤⤙≍ 3 ⧻₁ °△2_3_4_5
⍤⤙≍ 4 ⧻₋₂ °△2_3_4_5
# Subscripted shape
⍤⤙≍ 2_3 △₂ °△2_3_4_5
⍤⤙≍ 4_5 △₋₂ °△2_3_4_5
# Parse
⍤⤙≍ 5 ⍣⋕0 "5"
⍤⤙≍ 0 ⍣⋕0 "dog"
⍤⟜≍ ⟜≡⍜°⋕∘ [0 ¯1 η π τ ∞ ¯π NaN]
⍤⤙≍ [12 34 56] ⋕ ["12""34""56"]
⍤⤙≍ [1 23 456] ⋕ {"1""23""456"}
⍤⤙≍ "5" °⋕5
⍤⤙≍ {"1""2""3"} °⋕[1 2 3]
⍤⤙≍ [2 10 5] ⬚5⋕{"2" "10" "dog"}
⍤⤙≍ [ℂ 3.4e6 1.2 ℂ π ∞] ⋕ {"1.2r3.4e6i" "infrpii"}
⍤⟜≍ ⋕⊸°⋕ [ℂ 3.4e6 1.2 ℂ π ∞]
⍤⤙≍ [ℂ4.5 ¯12.3 ℂ4.5 12.3 ℂ¯4.5 12.3 ℂ¯4.5 12.3 ℂ4.5 12.3] ⋕{"-12.3r4.5i" "12.3r4.5i" "12.3-4.5i" "12.3r-4.5i" "12.3r4.5i"}
⍤⤙≍ [ℂ4 ¯12 ℂ4 12 ℂ¯4 12 ℂ¯4 12 ℂ4 12] ⋕{"-12r4i" "12r4i" "12-4i" "12r-4i" "12r4i"}
⍤⤙≍ [ℂ¯∞ π ℂ∞ π ℂτ π ℂ¯τ π ℂτ ¯π] ⋕{"πr-∞i" "πr∞i" "πrτi" "πr-τi" "-πrτi"}
⍤⤙≍ [ℂ¯∞ π ℂ∞ π ℂτ π ℂ¯τ π ℂτ ¯π] ⋕{"π-∞i" "π+∞i" "π+τi" "π-τi" "-π+τi"}
⍤⤙≍ ["12.1 " " 3 " " 6.25"] ⬚@ °⋕ [12.1 3 6.25]
⍤⤙≍ ["12.10" "03.00" "06.25"] ⬚@0°⋕ [12.1 3 6.25]
⍤⤙≍ ["001""382""023"] ⬚@0°⋕ [1 382 23]
⍤⤙≍ ¯1 ⬚¯1⋕ "Franklin County, Mississippi"
⍤⤙≍ map "ab" [123 456] ⋕ map "ab" {"123" "456"}
⍤⤙≍ map "ab" {"123" "456"} °⋕ map "ab" [123 456]
# Subscripted parse
⍤⤙≍ 3203386110 ⋕₁₆ "beefcafe"
⍤⤙≍ 42 ⋕₂ "101010"
⍤⤙≍ ¯42 ⋕₂ "-101010"
⍤⤙≍ π ⋕₈ "3.11037552421026430215"
⍤⤙≍ 623741435 ⋕₃₆ "aBcXyZ"
⍤⤙≍ 1/17 ⋕₁₇ ".1"
⍤⤙≍ 6 ⋕₁ "111111"
⍤⤙≍ ¯1 ⍣⋕₂¯1 "101020"
⍤⤙≍ [255 2748 16 ∞] ⬚∞⋕₁₆{"ff" "ABC" "10" "Z"}
⍤⤙≍ "Many hands make light work." ⇌°utf₈°⋯↯∞_8⋯≡⋕₆₄⇌ "TWFueSBoYW5kcyBtYWtlIGxpZ2h0IHdvcmsu"
⍤⤙≍ τ ⋕₆ "10.1411001432342522145"
⍤⤙≍ ¯1 ⍣(⋕₁₀|¯1) "inf"
⍤⤙≍ "a3" °⋕₁₂ 123
⍤⤙≍ "ff00ff" ♭⬚@0°⋕₁₆ ×255 Magenta
⍤⤙≍ τ_(√10)_6 ⋕₃°⋕₃ τ_(√10)_6
⍤⤙≍ τ_(√10)_6 ⋕₃₆°⋕₃₆ τ_(√10)_6
⍤⤙≍ "11111" °⋕₁ 5
⍤⤙≍ "0.111111111111111111111111111" °⋕₄ 1/3
⍤⤙≍ ¯1 ⍣(°⋕₁₀|¯1) ∞
⍤⤙≍ ["AB""CR""AO""AT""DG""AK"] ⬚@A°⋕₆₄ 1_145_14_19_198_10
# Where
⍤⤙≍ [0 3 5 6] ⊚[1 0 0 1 0 1 1 0]
⍤⤙≍ [1 2 2 3 3 3 4 4 4 4] ⊚[0 1 2 3 4]
⍤⤙≍ [1 0 0 1 0 1 1] °⊚[0 3 5 6]
⍤⤙≍ [1 0 0 1 0 1 1] °⊚[6 0 3 5]
⍤⤙≍ [0 1 2 3 4] °⊚[1 2 2 3 3 3 4 4 4 4]
# Multi-dimensional where
⍤⤙≍ [0_2 1_1 1_2 1_2] ⊚[0_0_1 0_1_2 0_0_0]
⍤⤙≍ [0_0_0_0 0_2_0_0 0_0_0_1] °⊚[2_3 1_1 1_1]
# Classify
⍤⤙≍ [0 1 2 3 4] ⊛ [2 9 4 8 3]
⍤⤙≍ [0 1 2 3 4] ⊛ ↯5_2⇡10
⍤⤙≍ [0 1 0 1 0] ⊛ ↯5_2⇡4
A ← [[1_2 1_2] [3_3 1_2]]
⍤⤙≍ [0 1] ⊛ A
⍤⤙≍ [0_0 0_1] ≡⊛ A
⍤⤙≍ [[0_1 0_1] [0_0 0_1]] ≡≡⊛ A
⍤⤙≍ [[0_0 0_0] [0_0 0_0]] ≡≡≡⊛ A
⍤⤙≍ [0 0] ⊛ °△2_0
⍤⤙≍ map [1 2 3] [0 1 0] ⊛ map [1 2 3] "aba"
⍤⤙≍ map 2 0 ⊛ map 2 @x
⍤⤙≍ [0 1 2] ⊛₀ [1 2 3]
⍤⤙≍ 0 ⊛₁ [1 2 3]
⍤⤙≍ 0 ⊛₂ [1 2 3]
⍤⤙≍ [0_0 1_2 0_0] ⊛₀ [1_1 3_4 1_1]
⍤⤙≍ [0 1 0] ⊛₁ [1_1 3_4 1_1]
⍤⤙≍ 0 ⊛₂ [1_1 3_4 1_1]
⍤⤙≍ °△2_0 ⊛₀ °△2_0
⍤⤙≍ [0 0] ⊛₁ °△2_0
# Deduplicate
⍤⤙≍ [1 2 3 4 5] ◴ [1 2 3 4 5]
⍤⤙≍ [1 2 3 4 5] ◴ [1 2 3 4 5 5 5 5 5 5]
⍤⤙≍ [1 2 3 4 5] ◴ [1 2 2 2 2 2 3 4 5 5]
⍤⤙≍ [4 8 2 9 1 3] ◴ [4 8 2 9 1 8 3 9 4 9 2 8]
⍤⤙≍ [1_2 3_4 5_6] ◴ [1_2 3_4 5_6 3_4]
# Bits
⍤⟜≍ ⟜⍜⋯∘ 5
⍤⟜≍ ⟜⍜⋯∘ 15
⍤⟜≍ ⟜⍜⋯∘ [1 2 3]
⍤⟜≍ ⟜⍜⋯∘ [1_2_3 4_5_6]
⍤⟜≍ ⟜⍜°⋯∘ [1 0 1]
⍤⟜≍ ⟜⍜°⋯∘ [1 1 1 1]
⍤⟜≍ ⟜⍜°⋯∘ [0_1 1_0]
⍤⟜≍ ⟜⍜⋯∘ 0
⍤⟜≍ ⟜⍜⋯∘ [0]
⍤⟜≍ ⟜⍜⋯∘ [0 0 0]
⍤⟜≍ ⟜⍜⋯∘ [[]]
⍤⟜≍ ⟜⍜⋯∘ [[0]]
⍤⟜≍ ⟜⍜°⋯∘ []
⍤⟜≍ ⟜⍜°⋯∘ [[]]
⍤⟜≍ ⟜⍜⋯∘ ¯1
⍤⟜≍ ⟜⍜⋯∘ [¯1]
⍤⤙≍ 13 °⋯₃ [1 0 1 1]
⍤⤙≍ [1 0 1 0 0 0 0 0] ⋯₈ 5
⍤⤙≍1 /+⋯₁₂₇ 1
⍤⤙≍1 /+⋯₁₂₈ 1
⍤⤙≍1 /+⋯₂₅₇ 1
⍤⤙≍1 /+⋯₁₀₀₀ 1
⍤⤙≍2 /+⋯₁₀₀₀ 10
⍤⤙≍8 /+⋯₁₀₀₀ 3802 # arbitrary
⍤⤙≍128 ⧻⋯₁₂₈ 1
⍤⤙≍257 ⧻⋯₂₅₇ 1
⍤⤙≍1000 ⧻⋯₁₀₀₀ 1
⍤⤙≍1000 ⧻⋯₁₀₀₀ 10
⍤⤙≍10000 ⧻⋯₁₀₀₀₀ 3802 # arbitrary
⍤⤙≍ 1.5 ⍣⋯∘ 1.5
# Json
⍤⤙≍ "[1,2,3]" json [1 2 3]
⍤⤙≍ "[\"some\",\"words\"]" json {"some" "words"}
⍤⤙≍ "{\"buddy\":[3,4,5],\"hey\":1,\"there\":2}" json map {"hey" "there" "buddy"} {1 2 [3 4 5]}
⍤⤙≍ "[true,false]" json [True False]
⍤⤙≍ [4 5 6] °json "[4,5,6]"
⍤⤙≍ {"what's" "the" "plan"} °json $ ["what's","the","plan"]
⍤⤙≍ ⇌map {"foo" "baz"} {"bar" 1_2_3} °json $ {"foo": "bar", "baz": [1, 2, 3]}
⍤⤙≍ [True False] °json "[true,false]"
json insert "b" True map {"a"} {1_2_3_4}
⍤⤙≍ $ {"a":[1,2,3,4],"b":true}
json₅ map {"foo" "bar"} {"hello" [1 2 3]}
$ {
$ bar: [
$ 1,
$ 2,
$ 3,
$ ],
$ foo: "hello",
$ }
⍤⤙≍
# Csv
⍤⟜≍ ⟜⍜csv∘ [{"hi" "there"} {"my" "friend"}]
⍤⤙≍ ⟜(⋕ ⍜csv∘) ↯3_4⇡12
⍤⤙≍ ⟜(≡⍣⋕∘ ⍜csv∘) [{"Foo" "Bar"} [1 2] [3 4] [5 6]]
⍤⤙≍ [{"1" "2" ""} {"3" "" ""} {"4" "5" "6"}] °csv "1,2\n3\n4,5,6\n"
⍤⤙≍ [{"1" "2" ""} {"3" "" ""} {"4" "5" "6"}] °⬚@;csv "1;2\n3\n4;5;6\n"
⍤⤙≍ [{"1" "2" "x"} {"3" "x" "x"} {"4" "5" "6"}] ⬚"x"°⬚@;csv "1;2\n3\n4;5;6\n"
⍤⤙≍ "1,2\n3\n4,5,6\n" csv {1_2 3 4_5_6}
⍤⤙≍ "1;2\n3\n4;5;6\n" ⬚@;csv {1_2 3 4_5_6}
# Datetime
⍤⤙≍ [2023 2 28 1 2 3] ⍜°datetime∘ [2023 2 28 1 2 3]
⍤⤙≍ [2023 3 1 1 2 3] ⍜°datetime∘ [2023 2 29 1 2 3]
⍤⤙≍ [2024 1 1 0 0 0] ⍜°datetime∘ [2024]
⍤⤙≍ [2024 7 1 0 0 0] ⍜°datetime∘ [2024.5]
⍤⤙≍ [2023 12 1 0 0 0] ⍜°datetime∘ [2024 0]
⍤⤙≍ [2023 11 30 0 0 0] ⍜°datetime∘ [2024 0 0]
# Repr
repr[{[[1 2][2 3]][3 4]}{[[1 2][2 3]]□{[[1 2][2 3]]□□[3 4]}}]
"[{[[1 2] [2 3]] [3 4]}\n {[[1 2] [2 3]] □{[[1 2] [2 3]] □□[3 4]}}]"
⍤⤙≍
⍤⤙≍ {"\"test\"" "ℂ1.5 ¯0.0004" "□\"box\""} ⍚repr {"test" ℂ3/2 ¯4e¯4 □"box"}
⍚repr{@⊗ @ @\0 @' @\\ @\u{1f600} @\x13 @\u{99999} "你好"}
⍤⤙≍ {"@⊗" "@\\s" "@\\0" "@'" "@\\\\" "@😀" "@\\x13" "@\\u{99999}" "\"你好\""}
⍤⤙≍ "\"n\\n\\\\n \\t \\\" ' \"" repr "n\n\\n \t \" ' "
⍤⤙≍ "{¯i ¯π W}" repr {¯i ¯π W}
⍤⤙≍ "[True False]" repr [True False]
⍤⤙≍ "$x 5" repr $x 5
ReprTest! ←^ ˙$"\"_\" repr _" °□⊢
⍤⤙≍ ReprTest!(°△2_0)
⍤⤙≍ ReprTest!(°△2_0_1)
⍤⤙≍ ReprTest!(°△2_0_0)
⍤⤙≍ ReprTest!(°△0_2)
⍤⤙≍ ReprTest!(°△0_2_0)
⍤⤙≍ ReprTest!(°△0_2_1)
⍤⤙≍ ReprTest!(+@a°△0_2)
⍤⤙≍ ReprTest!(ℂ0°△0_2)
⍤⤙≍ ReprTest!(≡₀□°△0_2)
# Sort
⍤⤙≍ [1 2 4 4 8] ⍆ [4 8 2 1 4]
⍤⤙≍ [2_1_1 5_2_0 5_3_5] ⍆ [5_3_5 2_1_1 5_2_0]
# Rise and fall
⍤⤙≍ [1 2 0] ⍏ [2 1 1]
⍤⤙≍ [2 0 1] ⍖ [1 1 2]
# HSV
⍤⤙≍ [0 5/9 0.9] hsv [0.9 0.4 0.4]
⍤⤙≍ [τ/3 5/9 0.9] hsv [0.4 0.9 0.4]
⍤⤙≍ [2τ/3 5/9 0.9] hsv [0.4 0.4 0.9]
⍤⤙≍ [0 0.5 1 0.5] hsv [1 0.5 0.5 0.5]
⍤⤙≍ ⟜⍜hsv∘ [Red Orange Yellow Green Cyan Blue Purple Magenta]
⍤⤙≍ ⟜⍜hsv∘ [Red Orange Yellow Green Cyan Blue Purple Magenta]
⍤⤙≍ ∩(⁅₁₂♭) ⟜⍜hsv∘ ▽⟜≡▽0.5 Lena
# FFT
⍤⤙≍ ⟜⍜fft∘ ℂ0[1 2 3 4]
⍤⤙≍ ⟜⍜°fft∘ ℂ0[1 2 3 4]
⍤⤙≍ ⟜(⁅₁₀⍜fft∘) ℂ0[1 2 3]
⍤⤙≍ ⟜(⁅₁₀⍜°fft∘) ℂ0[1 2 3 5]
⍤⤙≍ ⟜(⁅₁₀⍜fft∘) ℂ0°△3_3
⍤⤙≍ ⟜(⁅₁₀⍜°fft∘) ℂ0[1 2 3]
⍤⤙≍ ⟜(⁅₁₀⍜fft∘) ℂ0[1 2 3 5]
⍤⤙≍ ⟜(⁅₁₀⍜°fft∘) ℂ0°△3_3
# Experimental!
# Occurrences
⍤⤙≍ ↯5 0 ⧆ ⇡5
⍤⤙≍ [0 0 0 0 0 0 1 1 0 2 0] ⧆ "lego helmet"
⍤⤙≍ [0 0 1 0] ⧆ [1_2 4_3 1_2 3_0]
⍤⤙≍ [1 1 1 1 1] ⧆₁ [1 2 3 4 5]
⍤⤙≍ [1 1 1 1 1 0 0 0 0 0] ⧆₁ [1 2 3 4 5 5 5 5 5 5]
⍤⤙≍ [1 1 1 1 1 1 0 0 0 0] ⧆₂ [1 2 3 4 5 5 5 5 5 5]
⍤⤙≍ [1 1 1 1 1 0 1 0 0 0 0 0] ⧆₁ [4 8 2 9 1 8 3 9 4 9 2 8]
⍤⤙≍ [1 1 1 0] ⧆₁ [1_2 3_4 5_6 3_4]
# Exp
⍤⤙≍ 1 °ₑ e
⍤⤙≍ 1 ₑ 0
⍤⤙≍ e ₑ 1
⍤⤙≍ 6 °ₑ₂ 64
⍤⤙≍ 64 ₑ₂ 6
⍤⤙≍ [0 1 2 3 4 5 6 7] °ₑ₁₀ [1e0 1e1 1e2 1e3 1e4 1e5 1e6 1e7]
⍤⤙≍ [0 1 2 3 4 5 6 7] °ₑ₂ [1 2 4 8 16 32 64 128]
# Binary round-trip
⍤⤙≍ ⟜⍜binary∘ [1 2 3 4]
⍤⤙≍ ⟜⍜binary∘ {"Hello" "World!"}
⍤⤙≍ ⟜⍜binary∘ °△2_3_4_5
⍤⤙≍ ⟜⍜binary∘ {1 η_π_τ 4_5_6 "wow!"}
⍤⤙≍ ⟜⍜binary∘ map [1 2 3] [4 5 6]
⍤⤙≍ ⟜⍜binary∘ ⇡256
⍤⤙≍ ⟜⍜binary∘ ⇡257
⍤⤙≍ ⟜⍜binary∘ ÷⟜⇡256
⍤⤙≍ ⟜⍜binary∘ ×π ⇡256
# Unredmul (factorization)
⍤⤙≍ [2 3] °/× 6
⍤⤙≍ [3 3] °/× 9
⍤⤙≍ [2 2 3] °/× 12
⍤⤙≍ [3 17] °/× 51
⍤⤙≍ [7 7] °/× 49
⍤⤙≍ [67] °/× 67
⍤⤙≍ ↯32 2 °/× ₑ₂32
⍤⤙≍ ↯33 2 °/× ₑ₂33
⍤⤙≍ ↯40 2 °/× ₑ₂40
⍤⤙≍ [2 2 5 5 13 41 61 1321] °/× 4294967300
⍤⤙≍ [2 59 83 239 469723] °/× 1099511627818
⍤⤙≍ ≡/×⊸⬚1≡°/× ⇡₁500
⍤⤙≍ [1_1_1_2_1 1_2_3_2_5] °/× ⇡₁5
⍤⤙≍ [3_7_1 17_7_67] °/× 51_49_67
⍤⤙≍ ↯2_1_1_2 2_1_2_5 °/× ¤¤4_5
⍤⤙≍ ↯[4 5][2 1 1 1 2 2 1 2 1 2 5 1 3 1 2 5 101 17 103 13] °/× +100 ⇡5