uiua 0.18.1

A stack-based array programming language
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

{
  craneLib,
  makeBinaryWrapper,
  stdenv,
  lib,
  pkg-config,
  libffi,
  alsa-lib,
  rustPlatform,
  libGL,
  libxkbcommon,
  wayland,
  xorg,
  doCheck ? true,
}:
let
  libPath = lib.makeLibraryPath (
    lib.optionals stdenv.hostPlatform.isLinux [
      libGL
      libxkbcommon
      wayland
      xorg.libX11
      xorg.libXcursor
      xorg.libXi
      xorg.libXrandr
    ]
  );
  commonArgs = {
    src = lib.fileset.toSource {
      root = ../.;
      fileset = lib.fileset.unions (
        [
          (lib.fileset.fromSource (craneLib.cleanCargoSource ../.))
          ../src/assets
        ]
        ++ lib.optionals doCheck [
          ../site/favicon.ico
          ../tests
          ../tests_special
        ]
      );
    };
    strictDeps = true;
    cargoExtraArgs = "--features system,full";
    inherit doCheck;
    nativeBuildInputs = [
      pkg-config
      rustPlatform.bindgenHook
      makeBinaryWrapper
    ];
    buildInputs = [ libffi ] ++ lib.optionals stdenv.isLinux [ alsa-lib ];
    # https://crane.dev/faq/rebuilds-bindgen.html
    env.NIX_OUTPATH_USED_AS_RANDOM_SEED = "uiuarustbg";
  };
  cargoArtifacts = craneLib.buildDepsOnly commonArgs;
  totalArgs = commonArgs // {
    inherit cargoArtifacts;
    cargoTestExtraArgs = "-- --skip format::generate_format_cfg_docs";
    postInstall = ''
      wrapProgram "$out/bin/uiua" --prefix LD_LIBRARY_PATH : "${libPath}"
    '';
    passthru = {
      inherit libPath;
    };
  };
in
craneLib.buildPackage totalArgs