ufw-rule-parser 0.1.0

parser for a ufw-like firewall rule, including internal/external address keywords.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

WHITESPACE = _{ " " | "\t" }
NEWLINE    = _{ "\r\n" | "\n" }
COMMENT    = _{ "#" ~ (!NEWLINE ~ ANY)* }

action     = { "allow" | "deny" | "reject" | "limit" }
direction  = { "in" | "out" }

ident      = @{ (ASCII_ALPHANUMERIC | "_" | "-")+ }

ip         = @{ (ASCII_DIGIT | "." | "/")+ }
addr       = { "any" | "internal" | "external" | ip }

port_number   = @{ ASCII_DIGIT+ }
port_clause   = { "port" ~ port_number }

proto         = { "tcp" | "udp" | "any" }
proto_clause  = { "proto" ~ proto }

interface_clause = { "on" ~ ident }
from_clause = { "from" ~ addr }
to_clause   = { "to"   ~ addr }

addr_rule = {
    action
    ~ direction?
    ~ interface_clause?
    ~ (from_clause | to_clause | port_clause | proto_clause)+
}

service_rule = {
    action ~ ident
}

line = _{
    (addr_rule | service_rule) ~ COMMENT?
  | COMMENT
}

file = { SOI ~ (line? ~ NEWLINE)* ~ EOI }