ucobs 0.3.4

μCOBS — Consistent Overhead Byte Stuffing. no_std, zero-alloc, fastest, most-tested COBS implementation.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

# μCOBS development tasks

# default: list all recipes
default:
    @just --list

# run ALL quality gates (tests, clippy, fmt check, doc, deny, fuzz, miri, mutants)
test: test-unit test-clippy test-fmt test-doc test-deny test-fuzz test-miri test-mutants

# quick compile check (no tests)
check:
    cargo check

# unit + integration + proptest tests (via nextest for parallelism)
test-unit:
    cargo nextest run
    cargo nextest run --features legacy-msrv
    cargo test --doc

# clippy with all warnings as errors
test-clippy:
    cargo clippy -- -D warnings
    cargo clippy --features legacy-msrv -- -D warnings

# check formatting
test-fmt:
    cargo fmt -- --check

# doc build (catches broken doc links)
test-doc:
    cargo doc --no-deps --all-features

# license and advisory audit (requires cargo-deny)
test-deny:
    cargo deny check

# fuzz all targets (60s each, requires nightly + cargo-fuzz)
test-fuzz:
    cd fuzz && cargo +nightly fuzz run fuzz_decode -- -max_total_time=60
    cd fuzz && cargo +nightly fuzz run fuzz_encode -- -max_total_time=60
    cd fuzz && cargo +nightly fuzz run fuzz_roundtrip -- -max_total_time=60
    cd fuzz && cargo +nightly fuzz run fuzz_small_dest -- -max_total_time=60

# run tests under miri (catches UB, requires nightly + miri component)
# proptest is excluded — its file-persistence layer calls getcwd which miri does not support
test-miri:
    cargo +nightly miri test -- --skip proptests

# mutation testing (requires cargo-mutants)
test-mutants:
    cargo mutants --no-shuffle

# run iai-callgrind benchmarks (deterministic instruction counts, requires valgrind)
bench: bench-iai bench-size

# run iai-callgrind benchmarks (ucobs vs cobs vs corncobs)
bench-iai:
    cargo bench

# measure compiled code size (encode + decode .text bytes)
bench-size:
    @cargo build --release 2>/dev/null
    @echo ""
    @echo "Code size (release, encode + decode .text):"
    @nm -S target/release/libucobs.rlib 2>/dev/null \
        | grep 'T _ZN5ucobs' \
        | awk '{size=strtonum("0x"$2); name=$4; sub(/.*ucobs[0-9]*/, "", name); sub(/17h.*/, "", name); printf "  ucobs %-7s %4d B\n", name, size}'

# run python cobs benchmarks (requires: pip install cobs)
bench-python:
    python3 bench_python.py

# run all benchmarks (rust + python)
bench-all: bench bench-python

# format code
fmt:
    cargo fmt

# build in release mode
build:
    cargo build --release

# clean all build artifacts
clean:
    cargo clean
    rm -rf fuzz/target fuzz/corpus fuzz/artifacts