ttf-parser 0.6.2

A high-level, safe, zero-allocation TrueType font parser.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

QT       += widgets

CONFIG += c++14

CONFIG(release, debug|release): LIBS += -L$$PWD/../../c-api/target/release/ -lttfparser
else:CONFIG(debug, debug|release): LIBS += -L$$PWD/../../c-api/target/debug/ -lttfparser

INCLUDEPATH += $$PWD/../../c-api
DEPENDPATH += $$PWD/../../c-api

SOURCES += \
    glyphsview.cpp \
    main.cpp \
    mainwindow.cpp \
    ttfparserfont.cpp

HEADERS += \
    glyph.h \
    glyphsview.h \
    mainwindow.h \
    ttfparserfont.h

FORMS += \
    mainwindow.ui

# qmake DEFINES+=WITH_FREETYPE
contains(DEFINES, WITH_FREETYPE) {
    SOURCES += freetypefont.cpp
    HEADERS += freetypefont.h

    CONFIG += link_pkgconfig
    PKGCONFIG += freetype2
}

# qmake DEFINES+=WITH_HARFBUZZ HARFBUZZ_SRC=/path/to/harfbuzz-master/
contains(DEFINES, WITH_HARFBUZZ) {
    SOURCES += harfbuzzfont.cpp
    HEADERS += harfbuzzfont.h

    # harfbuzz should be built with cmake
    LIBS += -L$$HARFBUZZ_SRC/build -lharfbuzz
    INCLUDEPATH += $$HARFBUZZ_SRC/src
}