truck-rendimpl 0.2.0

visualization of shape and polygon mesh based on platform
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

#version 450

#include "microfacet-module.frag"

layout(location = 0) in vec3 position;
layout(location = 1) in vec2 uv;
layout(location = 2) in vec3 vertex_normal;
layout(location = 3) in flat uvec2 boundary_range;

layout(set = 0, binding = 0) uniform Camera {
    mat4 camera_matrix;
    mat4 camera_projection;
};

layout(set = 0, binding = 1) buffer Lights {
    Light lights[];
};

layout(set = 0, binding = 2) uniform Scene {
    float _time;
    uint nlights;
};

layout(set = 1, binding = 1) uniform ModelMaterial {
    Material material;
};

layout(set = 1, binding = 2) buffer Boundary {
    vec4 boundary[];
};

layout(location = 0) out vec4 color;

bool in_domain() {
    int score = 0;
    for (uint i = boundary_range[0]; i < boundary_range[1]; i++) {
        vec2 start = boundary[i].xy - uv;
        vec2 end = boundary[i].zw - uv;
        if (start[1] * end[1] >= 0) continue;
        float as = abs(start[1]);
        float ae = abs(end[1]);
        float x = (ae * start[0] + as * end[0]) / (as + ae);
        if (x > 0) {
            if (end[1] > 0) score += 1;
            else score -= 1;
        }
    }
    return score > 0;
}

void main() {
    if (!in_domain()) discard;
    Material mat = material;
    vec3 camera_dir = normalize(camera_matrix[3].xyz - position);
    vec3 normal = normalize(vertex_normal);
    vec3 pre_color = vec3(0.0, 0.0, 0.0);
    for (uint i = 0; i < nlights; i++) {
        Light light = lights[i];
        pre_color += microfacet_color(position, normal, light, camera_dir, mat);
    }
    pre_color = clamp(pre_color, 0.0, 1.0);
    pre_color = ambient_correction(pre_color, mat);
    color = vec4(pre_color, 1.0);
}