tracexec 0.17.0

Tracer for execve{,at} and pre-exec behavior, launcher for debuggers.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

localFlake:

{
  lib,
  config,
  self,
  inputs,
  ...
}:
{
  perSystem =
    { system, pkgs, ... }:
    {
      packages =
        let
          craneLib = localFlake.crane.mkLib pkgs;
          cFilter = path: _type: builtins.match ".*\.[ch]$" path != null;
          protoFilter = path: _type: builtins.match ".*\.proto$" path != null;
          symlinkFilter = _path: type: type == "symlink";
          sourceFilter =
            path: type:
            (cFilter path type)
            || (protoFilter path type)
            || (symlinkFilter path type)
            || (craneLib.filterCargoSources path type);
          builder =
            { cargoExtraArgs }:
            craneLib.buildPackage {
              inherit cargoExtraArgs;
              src = lib.cleanSourceWith {
                src = ./..;
                filter = sourceFilter;
                name = "source";
              };
              buildInputs = with pkgs; [
                elfutils
                zlib
                libseccomp
              ];
              nativeBuildInputs = with pkgs; [
                pkg-config
                clang # For building eBPF
                protobuf # For generating binding to perfetto protos
              ];
              hardeningDisable = [
                "zerocallusedregs"
              ];
              # Don't store logs
              TRACEXEC_DATA = "/tmp";
            };
        in
        {
          tracexec = builder { cargoExtraArgs = "--locked"; };
        };
    };
}