tmux-sessionizer 0.6.1

Tmux Sessionizer is a cli tool to fuzzy find all git repositories in a list of specified folders and open them as a new tmux session. Also, for git worktrees, this tool opens all checked out worktrees as new windows.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120

{
  description = "devShell for Rust projects";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane.url = "github:ipetkov/crane";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      flake-parts,
      rust-overlay,
      crane,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      perSystem =
        {
          config,
          self',
          inputs',
          pkgs,
          system,
          ...
        }:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [
              self.overlays.default
              (import rust-overlay)
            ];
          };
          packageVersion = (fromTOML (builtins.readFile ./Cargo.toml)).package.version;
          rustToolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
          craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
          commonArgs = with pkgs; {
            version = "${packageVersion}-${self.shortRev or "dirty"}";
            src = craneLib.cleanCargoSource ./.;
            strictDeps = true;

            nativeBuildInputs = [
              installShellFiles
            ];
            nativeCheckInputs = [
              git
            ];
          };
          cargoArtifacts = craneLib.buildDepsOnly commonArgs;
          tmux-sessionizer = craneLib.buildPackage (
            commonArgs
            // {
              inherit cargoArtifacts;
              postInstall =
                with pkgs;
                lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
                  installShellCompletion --cmd tms \
                    --bash <(COMPLETE=bash $out/bin/tms) \
                    --fish <(COMPLETE=fish $out/bin/tms) \
                    --zsh <(COMPLETE=zsh $out/bin/tms)
                '';
              meta.mainProgram = "tms";
            }
          );
        in
        {
          packages = rec {
            default = tmux-sessionizer;
            inherit tmux-sessionizer;
          };

          checks = {
            inherit (self.packages.${system}) tmux-sessionizer;
            clippy = craneLib.cargoClippy (
              commonArgs
              // {
                inherit cargoArtifacts;
                cargoClippyExtraArgs = "--all-targets --all-features -- --D warnings";
              }
            );
            fmt = craneLib.cargoFmt commonArgs;
            test = craneLib.cargoTest (
              commonArgs
              // {
                inherit cargoArtifacts;
              }
            );
          };

          devShells.default = craneLib.devShell {
            inputsFrom = [ tmux-sessionizer ];
            packages = with pkgs; [
              rust-analyzer
              cargo-dist
              rustup # required for cargo-dist
            ];
          };
        };

      flake = {
        overlays.default = final: prev: {
          inherit (self.packages.${final.stdenv.hostPlatform.system}) tmux-sessionizer;
        };

      };
    };
}