timewall 2.0.0

All-in-one tool for Apple dynamic HEIF wallpapers on GNU/Linux
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    rust-overlay,
    ...
  }: let
    supportedSystems = ["x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin"];

    # libheif 1.19.7 is not in nixpkgs-unstable yet
    libheif-overlay = final: prev: {
      libheif = prev.libheif.overrideAttrs (_self: _super: rec {
        version = "1.19.7";
        src = final.fetchFromGitHub {
          owner = "strukturag";
          repo = "libheif";
          rev = "v${version}";
          hash = "sha256-FXq6AOq1tUM05++fkzowApbLnlgeS5ZJ+UmypHrF11g=";
        };
      });
    };

    forEachSystem = f:
      nixpkgs.lib.genAttrs supportedSystems (system:
        f (import nixpkgs {
          inherit system;
          overlays = [
            rust-overlay.overlays.default
            libheif-overlay
          ];
        }));
    rev = self.shortRev or self.dirtyShortRev or "dirty";
  in {
    devShells = forEachSystem (pkgs: {
      default = pkgs.mkShell {
        packages = with pkgs; [
          (rust-bin.fromRustupToolchainFile ./rust-toolchain.toml)
          cargo-llvm-cov
          just
        ];

        buildInputs = with pkgs; [
          libheif
        ];

        nativeBuildInputs = with pkgs; [
          pkg-config
        ];
      };
    });

    overlays.default = final: prev: {
      timewall = final.callPackage ./nix/package.nix {inherit rev;};
    };

    packages = forEachSystem (pkgs: rec {
      timewall = pkgs.callPackage ./nix/package.nix {inherit rev;};
      default = timewall;
    });

    homeManagerModules = rec {
      timewall = import ./nix/hm-module.nix self;
      default = timewall;
    };

    formatter = forEachSystem (pkgs: pkgs.alejandra);
  };
}