thrum 0.0.4

A terminal email client
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix.url = "github:nix-community/fenix";
    fenix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      fenix,
    }:
    {
      overlays.default = final: prev: {
        thrum = final.rustPlatform.buildRustPackage {
          pname = "thrum";
          version = "0.0.4";
          src = self;
          cargoLock.lockFile = ./Cargo.lock;
          nativeBuildInputs = [ final.pkg-config ];
          buildInputs =
            [ final.openssl ]
            ++ final.lib.optionals final.stdenv.hostPlatform.isDarwin [
              final.darwin.apple_sdk.frameworks.Security
              final.darwin.apple_sdk.frameworks.SystemConfiguration
            ];
        };
      };
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          system = system;
          overlays = [ self.overlays.default ];
        };
        devPackages = with pkgs; [
          cargo-info
          cargo-udeps
          just
          pkg-config
          (
            with fenix.packages.${system};
            combine [
              complete.rustc
              complete.rust-src
              complete.cargo
              complete.clippy
              complete.rustfmt
              complete.rust-analyzer
            ]
          )
        ];

        libraries = with pkgs; [
          openssl
        ];
      in
      {
        packages.default = pkgs.thrum;

        devShell = pkgs.mkShell {
          buildInputs = devPackages ++ libraries;

          LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath libraries;
        };
      }
    );
}