tern 3.1.6

Embedded database migrations in SQL or Rust.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125

{ lib, ... }:
let
  perSystem =
    { crane, ... }:
    let
      root = ../.;

      # The smallest fileset contains the Cargo.toml and the Cargo.lock file to
      # build only the workspace deps.
      cargoTomlAndLock = crane.fileset.cargoTomlAndLock root;
      # The set of *.rs, Cargo.toml, Cargo.lock files.
      src = crane.fileset.commonCargoSources root;

      inherit (crane.crateNameFromCargoToml { src = crane.cleanCargoSource ../.; }) pname version;

      args = {
        # Override if building with `-p`.
        inherit pname version;
        src = lib.fileset.toSource {
          inherit root;
          fileset = src;
        };
        strictDeps = true;
        cargoBuildExtraArgs = "--all-features";
      };

      # Build only dependencies so that they can be cached for everything else.
      cargoArtifacts = crane.buildDepsOnly {
        inherit (args) pname version cargoBuildExtraArgs;

        src = lib.fileset.toSource {
          inherit root;
          fileset = cargoTomlAndLock;
        };
        strictDeps = true;
      };

      mkTernPackage =
        pname:
        crane.buildPackage {
          inherit pname cargoArtifacts;
          inherit (args)
            src
            version
            strictDeps
            ;
          cargoBuildExtraArgs = "--all-features -p ${pname}";
        };

      # Individual crates as flake outputs.
      tern-cli = mkTernPackage "tern-cli";
      tern-core = mkTernPackage "tern-core";
      tern-derive = mkTernPackage "tern-derive";

      # The root package.
      tern = crane.buildPackage {
        inherit cargoArtifacts;
        inherit (args)
          src
          pname
          version
          strictDeps
          ;
      };
    in
    {
      packages = {
        inherit
          tern
          tern-cli
          tern-core
          tern-derive
          ;

        default = tern;
      };

      checks = {
        # Build the crates as part of `nix flake check` for convenience.
        inherit
          tern
          tern-cli
          tern-core
          tern-derive
          ;

        tern-clippy = crane.cargoClippy {
          inherit (args)
            src
            strictDeps
            pname
            version
            ;

          inherit cargoArtifacts;
          cargoClippyExtraArgs = "--all-features --all-targets -- -Dwarnings";
        };

        tern-test = crane.cargoTest {
          inherit (args)
            strictDeps
            pname
            version
            ;
          inherit cargoArtifacts;

          cargoTestExtraArgs = "--all-features --all-targets";
          # We need to add the migration directories for the examples since
          # everywhere else they're filtered out and we need them to compile
          # tests (which includes `examples`).
          src = lib.fileset.toSource {
            inherit root;
            fileset = lib.fileset.unions [
              src
              ../examples/dynamic/migrations
              ../examples/simple/migrations
            ];
          };
        };
      };
    };
in
{
  inherit perSystem;
}