tauri-plugin-bare-kit 0.2.1

Effortless JavaScript backends for Tauri apps - Android 🤖 iOS 📱Linux 🐧 Macos 🖥️ Windows 💩
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164

function(add_bare_module result)
  bare_module_target("." target NAME name)

  if(NOT TARGET ${target})
    add_library(${target} OBJECT)

    set_target_properties(
      ${target}
      PROPERTIES
      C_STANDARD 11
      CXX_STANDARD 20
      POSITION_INDEPENDENT_CODE ON
    )

    target_include_directories(
      ${target}
      PRIVATE
        $<TARGET_PROPERTY:bare,INTERFACE_INCLUDE_DIRECTORIES>
    )
  endif()

  set(${result} ${target})

  return(PROPAGATE ${result})
endfunction()

function(add_napi_module result)
  napi_module_target("." target NAME name)

  if(NOT TARGET ${target})
    add_library(${target} OBJECT)

    set_target_properties(
      ${target}
      PROPERTIES
      C_STANDARD 11
      CXX_STANDARD 20
      POSITION_INDEPENDENT_CODE ON
    )

    target_include_directories(
      ${target}
      PRIVATE
        $<TARGET_PROPERTY:bare,INTERFACE_INCLUDE_DIRECTORIES>
    )
  endif()

  set(${result} ${target})

  return(PROPAGATE ${result})
endfunction()

function(link_bare_modules receiver)
  set(option_keywords
    SHARED
  )

  set(one_value_keywords
    WORKING_DIRECTORY
  )

  set(multi_value_keywords
    EXCLUDE
  )

  cmake_parse_arguments(
    PARSE_ARGV 1 ARGV "${option_keywords}" "${one_value_keywords}" "${multi_value_keywords}"
  )

  if(ARGV_WORKING_DIRECTORY)
    cmake_path(ABSOLUTE_PATH ARGV_WORKING_DIRECTORY BASE_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}" NORMALIZE)
  else()
    set(ARGV_WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}")
  endif()

  if(ARGV_SHARED)
    set(SHARED SHARED)
  else()
    set(SHARED)
  endif()

  list_node_modules(
    packages
    WORKING_DIRECTORY "${ARGV_WORKING_DIRECTORY}"
  )

  foreach(base ${packages})
    cmake_path(APPEND base "package.json" OUTPUT_VARIABLE package_path)

    file(READ "${package_path}" package)

    string(JSON name ERROR_VARIABLE error GET "${package}" "name")

    if("${name}" IN_LIST ARGV_EXCLUDE)
      continue()
    endif()

    if("${name}" IN_LIST SEEN)
      continue()
    endif()

    list(APPEND SEEN "${name}")

    string(JSON addon ERROR_VARIABLE error GET "${package}" "addon")

    if(addon)
      link_bare_module(
        ${receiver}
        ${base}
        ${SHARED}
        WORKING_DIRECTORY "${ARGV_WORKING_DIRECTORY}"
      )
    endif()
  endforeach()
endfunction()

function(generate_builtins)
  set(one_value_keywords
    WORKING_DIRECTORY
  )

  cmake_parse_arguments(PARSE_ARGV 0 ARGV "" "${one_value_keywords}" "")

  if(ARGV_WORKING_DIRECTORY)
    cmake_path(ABSOLUTE_PATH ARGV_WORKING_DIRECTORY BASE_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}" NORMALIZE)
  else()
    set(ARGV_WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}")
  endif()

  list_node_modules(
    packages
    WORKING_DIRECTORY "${ARGV_WORKING_DIRECTORY}"
  )

  set(builtins "[]")

  foreach(base ${packages})
    cmake_path(APPEND base "package.json" OUTPUT_VARIABLE package_path)

    file(READ "${package_path}" package)

    string(JSON name ERROR_VARIABLE error GET "${package}" "name")

    string(JSON version ERROR_VARIABLE error GET "${package}" "version")

    if("${name}@${version}" IN_LIST SEEN)
      continue()
    endif()

    list(APPEND SEEN "${name}@${version}")

    string(JSON addon ERROR_VARIABLE error GET "${package}" "addon")

    if(addon)
      set(entry "{\"addon\": \"${name}@${version}\"}")

      string(JSON index ERROR_VARIABLE error LENGTH "${builtins}")

      string(JSON builtins ERROR_VARIABLE error SET "${builtins}" "${index}" "${entry}")
    endif()
  endforeach()

  file(WRITE "${CMAKE_BINARY_DIR}/builtins.json" "${builtins}")
endfunction()