taskfinder 2.8.0

A terminal user interface that extracts and displays tasks from plain text files.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

{
  description = "taskfinder - Display tasks from plain text files";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, fenix, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        rustToolchain = fenix.packages.${system}.latest.toolchain;

        cargoToml = pkgs.lib.importTOML ./Cargo.toml;
        manifest = cargoToml.package;
        binName = (builtins.head cargoToml.bin).name;
        cleanDescription =  pkgs.lib.removeSuffix "." manifest.description;

        package = with pkgs;
          rustPlatform.buildRustPackage rec {
            pname = manifest.name;
            version = manifest.version;

            src = fetchFromGitea {
              domain = "codeberg.org";
              owner = "kdwarn";
              repo = "taskfinder";
              rev = "v${version}";
              hash = "sha256-pEil5W05ALkKtBwRgi44dk9H5P6F2kDnGVzipvr5vGE="; 
            };

            useFetchCargoVendor = true;
            cargoHash = "sha256-u8zHTNbVY/IitNOMkUGQxucFbG93hH1EXeIJzllHhso="; 

            nativeBuildInputs = [ rustToolchain ];

            meta = with lib; {
              description = cleanDescription;
              homepage = manifest.repository;
              license = licenses.agpl3Plus;
              maintainers = with maintainers; [ Ginner ];
              platforms = platforms.all;
              mainProgram = binName;
            };
          };
      in
      {
        packages.default = package;

        apps.default = flake-utils.lib.mkApp {
          drv = package;
          name = binName;
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            rustToolchain
            rust-analyzer
            clippy
          ];
        };
      }) // {
        overlays.default = final: prev: {
          taskfinder = self.packages.${prev.system}.default;
        };
      };
}