synta 0.2.2

ASN.1 parser, decoder, and encoder library with DER/BER support and C FFI
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# FindSynta.cmake
# CMake find module for the Synta ASN.1 library
#
# This module defines:
#  Synta_FOUND - System has Synta
#  Synta_INCLUDE_DIRS - The Synta include directories
#  Synta_LIBRARIES - The libraries needed to use Synta
#  Synta_VERSION - The version of Synta

find_package(PkgConfig QUIET)
if(PKG_CONFIG_FOUND)
    pkg_check_modules(PC_Synta QUIET synta)
endif()

find_path(Synta_INCLUDE_DIR
    NAMES synta.h
    PATHS ${PC_Synta_INCLUDE_DIRS}
    PATH_SUFFIXES synta
)

find_library(Synta_LIBRARY
    NAMES csynta libcsynta
    PATHS ${PC_Synta_LIBRARY_DIRS}
)

if(PC_Synta_VERSION)
    set(Synta_VERSION ${PC_Synta_VERSION})
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(Synta
    REQUIRED_VARS
        Synta_LIBRARY
        Synta_INCLUDE_DIR
    VERSION_VAR Synta_VERSION
)

if(Synta_FOUND)
    set(Synta_LIBRARIES ${Synta_LIBRARY})
    set(Synta_INCLUDE_DIRS ${Synta_INCLUDE_DIR})

    if(NOT TARGET Synta::Synta)
        add_library(Synta::Synta UNKNOWN IMPORTED)
        set_target_properties(Synta::Synta PROPERTIES
            IMPORTED_LOCATION "${Synta_LIBRARY}"
            INTERFACE_INCLUDE_DIRECTORIES "${Synta_INCLUDE_DIR}"
        )
    endif()
endif()

mark_as_advanced(Synta_INCLUDE_DIR Synta_LIBRARY)