steamux 0.1.0

Run multiple programs and interactive shells in one Proton's environment (Steam/umu-launcher)
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

{
  description = "Run multiple programs and interactive shells in one Proton's environment (Steam/umu-launcher)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    flake-parts.url = "github:hercules-ci/flake-parts";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [ "x86_64-linux" ];

      perSystem =
        {
          self',
          system,
          pkgs,
          lib,
          ...
        }:
        let
          craneLib = (inputs.crane.mkLib pkgs).overrideToolchain (p:
            p.rust-bin.beta.latest.default.override {
              extensions = [ "rust-src" "rust-analyzer" ];
            }
          );

          commonArgs = {
            src = craneLib.cleanCargoSource ./.;
            strictDeps = true;
          };

          steamux = craneLib.buildPackage (
            commonArgs
            // {
              cargoArtifacts = craneLib.buildDepsOnly commonArgs;
            }
          );
        in
        {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ (import inputs.rust-overlay) ];
          };

          checks = { inherit steamux; };

          packages = {
            inherit steamux;
            default = steamux;
          };

          apps = {
            steamux = {
              type = "app";
              program = lib.getExe steamux;
            };

            default = self'.apps.steamux;
          };

          devShells.default = craneLib.devShell {
            checks = self'.checks;
            inputsFrom = [ steamux ];
          };
        };
    };
}