staticrypt 1.0.3

Static encryption for string literals and binary data
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107

{
  description = "Rust crate for static encryption.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";

    crane.url = "github:ipetkov/crane";

    fenix.url = "github:nix-community/fenix";
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      fenix,
    }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      forEachSupportedSystem =
        f:
        nixpkgs.lib.genAttrs supportedSystems (
          system:
          let
            pkgs = import nixpkgs {
              inherit system;
              overlays = [ fenix.overlays.default ];
            };

            rustToolchain = pkgs.fenix.stable.withComponents [
              "cargo"
              "rustc"
              "rustfmt"
              "rust-analyzer"
              "clippy"
            ];

            craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;

            craneArgs = {
              src = craneLib.cleanCargoSource ./.;
              strictDeps = true;

              env = {
                RUST_BACKTRACE = "1";
                STATICRYPT_SEED = "01234567890123456789012345678901";
                RUSTFLAGS = "-Dwarnings";
                RUSTDOCFLAGS = "-Dwarnings";
              };
            };

            cargoArtifacts = craneLib.buildDepsOnly craneArgs;
          in
          f {
            inherit
              pkgs
              rustToolchain
              craneLib
              cargoArtifacts
              craneArgs
              ;
          }
        );
    in
    {
      devShells = forEachSupportedSystem (
        { pkgs, rustToolchain, ... }:
        {
          default = pkgs.mkShell {
            nativeBuildInputs = [
              rustToolchain
            ];

            STATICRYPT_SEED = "01234567890123456789012345678901";
          };
        }
      );

      checks = forEachSupportedSystem (
        {
          pkgs,
          craneLib,
          cargoArtifacts,
          craneArgs,
          ...
        }:
        {
          cargoDoc = craneLib.cargoDoc (craneArgs // { inherit cargoArtifacts; });

          cargoTest = craneLib.cargoTest (
            craneArgs
            // {
              inherit cargoArtifacts;

              postUnpack = ''
                cp ${./testfile.txt} ./source/testfile.txt
              '';
            }
          );
        }
      );
    };
}