spwn 0.0.6

A language for Geometry Dash triggers
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120

#[no_std, cache_output]
constants = import "constants.spwn"

extract constants.obj_props

type @event

impl @event {
    on: #[desc("Triggers a function every time an event fires") example("
on(touch(), !{
    10g.move(10, 0)
})
    ")] (
        #[desc("Event to trigger on")] event: @event,
        #[desc("Function to trigger")] function: @trigger_function
    ){
        event.on_triggered(function)
    }
}

return {

    touch: #[desc("Implementation of the touch trigger (returns an event)") example("
on(touch(), !{
    10g.move(10, 0)
})
    ")] (
        #[desc("Dual mode (only check for touch on the dual side)")] dual_side: @bool = false
    ) {
        return @event::{
            on_triggered: (function) => $.add( trigger{
                OBJ_ID: 1595,
                HOLD_MODE: true,
                TOGGLE_MODE: 1,
                TARGET: function,
                DUAL_MODE: dual_side,

            })
        }

    },

    touch_end: #[desc("Returns an event for when a touch ends") example("
on(touch_end(), !{
    10g.move(-10, 0)
})
    ")] (
        #[desc("Dual mode (only check for touch on the dual side)")] dual_side: @bool = false
    ) {
        return @event::{
            on_triggered: (function) => $.add( trigger{
                OBJ_ID: 1595,
                HOLD_MODE: true,
                TOGGLE_MODE: 2,
                TARGET: function,
                DUAL_MODE: dual_side,

            })
        }

    },

    collision: #[desc("Implementation of the collision trigger (returns an event)") example("
on(collision(1b, 2b), !{
    BG.set(255, 0, 0)
})
    ")] (
        #[desc("Block A ID")] a: @block,
        #[desc("Block B ID")] b: @block
    ) {
        return @event::{
            on_triggered: (function) => $.add( trigger{
                OBJ_ID: 1815,
                BLOCK_A: a,
                BLOCK_B: b,
                ACTIVATE_GROUP: true,
                ACTIVATE_ON_EXIT: false,
                TARGET: function,

            })
        }

    },

    collision_exit: #[desc("Returns an event for when a collision exits") example("
on(collision_exit(1b, 2b), !{
    BG.set(0, 0, 0)
})
    ")] (
        #[desc("Block A ID")] a: @block,
        #[desc("Block B ID")] b: @block
    ) {
        return @event::{
            on_triggered: (function) => $.add( trigger{
                OBJ_ID: 1815,
                BLOCK_A: a,
                BLOCK_B: b,
                ACTIVATE_GROUP: true,
                ACTIVATE_ON_EXIT: true,
                TARGET: function,

            })
        }
    },


    death: #[desc("Returns an event for when the player dies") example("
on(death(), !{
    BG.set(0, 0, 0)
})
    ")] (){
        return @event::{
            on_triggered: (function) => $.add( trigger{
                OBJ_ID: 1812,
                ACTIVATE_GROUP: true,
                TARGET: function
            })
        }
    }
}