solang 0.3.4

Solang Solidity Compiler
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89

/// SPDX-License-Identifier: Apache-2.0

contract token {
    address public admin;
    uint32 public decimals;
    string public name;
    string public symbol;

    constructor(
        address _admin,
        string memory _name,
        string memory _symbol,
        uint32 _decimals
    ) {
        admin = _admin;
        name = _name;
        symbol = _symbol;
        decimals = _decimals;
    }

    mapping(address => int128) public balances;
    mapping(address => mapping(address => int128)) public allowances;

    function mint(address to, int128 amount) public {
        require(amount >= 0, "Amount must be non-negative");
        admin.requireAuth();
        setBalance(to, balance(to) + amount);
    }

    function approve(address owner, address spender, int128 amount) public {
        require(amount >= 0, "Amount must be non-negative");
        owner.requireAuth();
        allowances[owner][spender] = amount;
    }

    function transfer(address from, address to, int128 amount) public {
        require(amount >= 0, "Amount must be non-negative");
        from.requireAuth();
        require(balance(from) >= amount, "Insufficient balance");
        setBalance(from, balance(from) - amount);
        setBalance(to, balance(to) + amount);
    }

    function transfer_from(
        address spender,
        address from,
        address to,
        int128 amount
    ) public {
        require(amount >= 0, "Amount must be non-negative");
        spender.requireAuth();
        require(balance(from) >= amount, "Insufficient balance");
        require(allowance(from, spender) >= amount, "Insufficient allowance");
        setBalance(from, balance(from) - amount);
        setBalance(to, balance(to) + amount);
        allowances[from][spender] -= amount;
    }

    function burn(address from, int128 amount) public {
        require(amount >= 0, "Amount must be non-negative");
        require(balance(from) >= amount, "Insufficient balance");
        from.requireAuth();
        setBalance(from, balance(from) - amount);
    }

    function burn_from(address spender, address from, int128 amount) public {
        require(amount >= 0, "Amount must be non-negative");
        spender.requireAuth();
        require(balance(from) >= amount, "Insufficient balance");
        require(allowance(from, spender) >= amount, "Insufficient allowance");
        setBalance(from, balance(from) - amount);
        allowances[from][spender] -= amount;
    }

    function setBalance(address addr, int128 amount) internal {
        balances[addr] = amount;
    }

    function balance(address addr) public view returns (int128) {
        return balances[addr];
    }

    function allowance(
        address owner,
        address spender
    ) public view returns (int128) {
        return allowances[owner][spender];
    }
}