sofka 0.5.1

A Kubernetes TUI, reimagined in Rust
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

set unstable
set shell := ["bash", "-eu", "-o", "pipefail", "-c"]

mod nix '.just/nix.just'
mod release '.just/release.just'
mod rust '.just/rust.just'

default:
    @just --list

# Install local git hooks.
hooks:
    lefthook install

# Format Rust sources.
fmt: rust::fmt

# Check Rust formatting without changing files.
fmt-check: rust::fmt-check

# Run clippy with the same policy as CI.
clippy: rust::clippy

# Run the unit test suite.
test: rust::test

# Fast local confidence check.
check: fmt-check clippy test

# Build the debug binary.
build: rust::build

# Build the release binary.
build-release: rust::build-release

# Run sofka against the current kube context.
run resource="pods":
    just rust run {{ resource }}

# Headless cluster connectivity check.
smoke: rust::smoke

# Render one headless UI snapshot.
snapshot resource="pods":
    just rust snapshot {{ resource }}

# Run Nix's flake checks.
nix-check: nix::check

# Build the Nix package.
nix-build: nix::build

# Build and smoke-test the Nix package.
nix-smoke: nix::smoke

# Release a patch version.
release-patch: release::patch

# Release a minor version.
release-minor: release::minor

# Release a major version.
release-major: release::major