snowcap 0.1.3

A simple markup language for iced
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

/* Snowcap pest grammar */

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }

container = {
    "{" ~ ("<" ~ attributes ~ ">")? ~ (row | column | stack | element)? ~ "}"
}

row    = { ("row" | "-") ~ ("<" ~ attributes ~ ">")? ~ element_list }
column = { ("col" | "|") ~ ("<" ~ attributes ~ ">")? ~ element_list }
stack  = { ("stack" | "^") ~ ("<" ~ attributes ~ ">")? ~ element_list }

element_list = _{ "[" ~ (element | row | column | stack | container) ~ ("," ~ (element | row | column | stack | container))* ~ "]" }

element    = { label ~ ("<" ~ attributes ~ ">")? ~ "(" ~ (element_value | element | container | row | column | stack | array)? ~ ")" }
pair       = { label ~ ":" ~ value }
attributes = { pair ~ ("," ~ pair)* }

element_value =  { value }
value         = _{ string | number | boolean | null | data_source }
array         =  { "[" ~ value ~ ("," ~ value)* ~ "]" }

data_source = { label ~ "!" ~ "(" ~ string ~ ")" }

boolean = { "true" | "false" }

null = { "null" }

label = @{ (ASCII_ALPHA | "-")* }

string = ${ "\"" ~ inner ~ "\"" }
inner  = @{ char* }
char   =  {
    !("\"" | "\\") ~ ANY
  | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t")
  | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}

number = @{
    "-"? ~ ("0" | ASCII_NONZERO_DIGIT ~ ASCII_DIGIT*) ~ ("." ~ ASCII_DIGIT*)? ~ (^"e" ~ ("+" | "-")? ~ ASCII_DIGIT+)?
}

markup = _{ SOI ~ (container) ~ EOI }