simplersble 1.0.1-dev21

The all-in-one Bluetooth library that makes it easy to add wireless connectivity to your projects.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Attempt to load DBus1 as CONFIG silently
find_package(DBus1 CONFIG QUIET)

if(TARGET DBus1::DBus1)
    set(DBus1_LIBRARIES DBus1::DBus1)
    set(DBus1_FOUND TRUE)
elseif(TARGET dbus-1)
    add_library(DBus1::DBus1 INTERFACE IMPORTED)
    target_link_libraries(DBus1::DBus1 INTERFACE dbus-1)
    set(DBus1_LIBRARIES DBus1::DBus1)
    set(DBus1_FOUND TRUE)
endif()

# If DBus1 was not found, try to find it through pkg-config.
if(NOT TARGET DBus1::DBus1)
    find_package(PkgConfig REQUIRED)

    if(NOT TARGET PkgConfig::DBus1)
        pkg_check_modules(DBus1 REQUIRED IMPORTED_TARGET dbus-1)
    endif()

    if(NOT TARGET dbus-1)
        add_library(dbus-1 INTERFACE IMPORTED)
        target_link_libraries(dbus-1 INTERFACE PkgConfig::DBus1)
    endif()

    add_library(DBus1::DBus1 INTERFACE IMPORTED)
    target_link_libraries(DBus1::DBus1 INTERFACE PkgConfig::DBus1)
    set(DBus1_LIBRARIES DBus1::DBus1)
    set(DBus1_FOUND TRUE)
endif()