sic_parser 0.23.0

Parser for the image operation script used by the 'imagineer' image cli
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107

WHITESPACE = _{ " "+ }
WS_OPT = _{ " "* }
sep = _{ ";" }
ident = @{ ASCII_ALPHANUMERIC+ }

bool = @{ "true" | "false" }
fp = @{ int ~ ("." ~ ASCII_DIGIT+)? }
uint = @{ ASCII_DIGIT+ }
int  = @{ "-"? ~ ASCII_DIGIT+ }

// string_unicode is based on https://pest.rs/book/examples/json.html
string_unicode = ${ (quot_double ~ string_inner ~ quot_double) | (quot_single ~ string_inner ~ quot_single) }
string_inner = @{ char* }
quotation = _{ quot_single | quot_double }
quot_single = _{ "'" }
quot_double = _{ "\"" }

char = {
    !quotation ~ ANY
    | "\\" ~ ("\"" | "\\" | "/" | "b" | "f" | "n" | "r" | "t")
    | "\\" ~ ("u" ~ ASCII_HEX_DIGIT{4})
}

named_value = ${ ident ~ "(" ~ arguments ~ ")" }
// note that all numbers (floating point, unsigned integers, integers etc.) are represented
// as "fp" (floating point representation) in the grammar
arg = _{ bool | fp | string_unicode }
arguments = _{ arg ~ (WS_OPT ~ "," ~ WS_OPT ~ arg)* }

triplet_sep = _{ WHITESPACE ~ "|" ~ WHITESPACE }
triplet_fp3 = _{ fp ~ WHITESPACE ~ fp ~ WHITESPACE ~ fp }

f3x3_args_sep = _{ triplet_fp3 ~ triplet_sep ~ triplet_fp3 ~ triplet_sep ~ triplet_fp3 }
f3x3_args_no_sep = _{ triplet_fp3 ~ WHITESPACE ~ triplet_fp3 ~ WHITESPACE ~ triplet_fp3 }

blur = ${ ^"blur" ~ WHITESPACE ~ fp }
brighten = ${ ^"brighten" ~ WHITESPACE ~ int }
contrast = ${ ^"contrast" ~ WHITESPACE ~ fp }
crop = ${ ^"crop" ~ WHITESPACE ~ uint ~ WHITESPACE ~ uint ~ WHITESPACE ~ uint ~ WHITESPACE ~ uint }
diff = ${ ^"diff" ~ WHITESPACE ~ string_unicode }
filter3x3 = ${ ^"filter3x3" ~ WHITESPACE ~ (f3x3_args_sep | f3x3_args_no_sep) }
flip_horizontal = { ^"flip-horizontal" }
flip_vertical = { ^"flip-vertical"  }
grayscale = { ^"grayscale" }
huerotate = ${ ^"hue-rotate" ~ WHITESPACE ~ int }
horizontal_gradient = ${ ^"horizontal-gradient" ~ WHITESPACE ~ named_value ~ WHITESPACE ~ named_value }
invert = { ^"invert" }
overlay = ${ ^"overlay" ~ WHITESPACE ~ string_unicode ~ WHITESPACE ~ uint ~ WHITESPACE ~ uint }
resize = ${ ^"resize" ~ WHITESPACE ~ uint ~ WHITESPACE ~ uint }
rotate90 = { ^"rotate90" }
rotate180 = { ^"rotate180" }
rotate270 = { ^"rotate270" }
threshold = { ^"threshold" }
unsharpen = ${ ^"unsharpen" ~ WHITESPACE ~ fp ~ WHITESPACE ~ int }
vertical_gradient = ${ ^"vertical-gradient" ~ WHITESPACE ~ named_value ~ WHITESPACE ~ named_value }

// example usage: draw-text "my text" rgba(10, 10, 255, 255) size(16)
draw_text = ${^"draw-text" ~ WHITESPACE ~ string_unicode ~ (WHITESPACE ~ named_value)*}

env_resize_sampling_filter_name = {^"sampling-filter"}
env_resize_preserve_aspect_ratio_name = {^"preserve-aspect-ratio"}

env_available = _{
      env_resize_sampling_filter_name
    | env_resize_preserve_aspect_ratio_name
}

set_resize_sampling_filter = ${env_resize_sampling_filter_name ~ WHITESPACE ~ ident }
set_resize_preserve_aspect_ratio = ${ env_resize_preserve_aspect_ratio_name ~ WHITESPACE ~ bool}

setenv_available = _{
	  set_resize_sampling_filter
    | set_resize_preserve_aspect_ratio
}

setopt = ${^"set" ~ WHITESPACE ~ setenv_available}
unsetopt = ${^"del" ~ WHITESPACE ~ env_available}

operation = _{
      blur
    | brighten
    | contrast
    | crop
    | diff
    | draw_text
    | filter3x3
    | flip_horizontal
    | flip_vertical
    | grayscale
    | huerotate
    | horizontal_gradient
    | invert
    | overlay
    | resize
    | rotate90
    | rotate180
    | rotate270
    | threshold
    | unsharpen
    | vertical_gradient
}

sequence = _{
	(operation | setopt | unsetopt ) ~ ( (NEWLINE* ~ EOI) | (sep ~ NEWLINE+) | sep)
}

main = _{ SOI ~ sequence* ~ EOI }